Frustrated Cook

Thread view:

Enable EMail Alerts

Start New Thread

Thread rating:

Wazza McG - 20 Nov 2005 20:41 GMT

Hi,

I have been having trouble trying to work out a formula for the following.

One cup of flour weighs 160g.

If I had 240g of flour I would have 1 1/2 Cups.

Now the hard bit, there are 16 Tablespoons and 48 teaspoons in a cup of
flour.

If I had 270g of flour I want the formula to have an end result of - 1 1/2
C, 2T and 3t - rounded off as close as possible.

In the cup measures, I would only want to use 1/4 C, 1/3 C, 1/2 C, 2/3 C,
3/4 C and 1C and so on. I know 5t should read 1T and 1t, however, getting a
formula to work is beyond me at this stage.

If anyone can help, It would be greatly appreciated.

Regards,

Wazza McG

Reply to this Message

Bernard Liengme - 20 Nov 2005 23:22 GMT

I bet you cannot measure a cup of flour with the accuracy that you are
suggesting.
Buy a metric scale and do it right!
best wishes

Signature

Bernard V Liengme
www.stfx.ca/people/bliengme
remove caps from email

> Hi,
>
[quoted text clipped - 19 lines]
>
> Wazza McG

Reply to this Message

Sandy Mann - 21 Nov 2005 00:08 GMT

I created a VLOOKUP table like:

E F G H I J
1 0 0C 0 0T 0 0t
2 40 1/4C 10 1T 33.33 1t
3 53.33 1/3C 20 2T 6.66 2t
4 80 1/2C 30 3T
5 106.67 2/3C 40 4T
6 120 3/4C 50 5T
7 160 1C 60 6T
8 200 1 1/4C 70 7T
9 213.33 1 1/3C 80 8T
10 240 1 1/2C 90 9T
11 266.66 1 2/3C 100 10T
12 280 1 3/4C 110 11T
13 320 2C 120 12T
14 360 2 1/4C 130 13T
15 373.33 2 1/3C 140 14T
16 400 2 1/2C 150 15T
17 426.67 2 2/3C
18 440 2 4/4C
19 480 3C

then with the flour in grams in A1 try:

=VLOOKUP(A1,E1:F19,2) &"
"&VLOOKUP(INT((A1-VLOOKUP(A1,E1:E19,1))/10),G1:H16,2)& "
"&VLOOKUP(ROUND(A1-VLOOKUP(A1,E1:E19,1)-INT((A1-VLOOKUP(A1,E1:E19,1))/10)*10,2),I1:J3,2)

there are tree spaces between the quotes but as Bernard said, buy metric
scale.

Signature

HTH

Sandy
sandymann@mailinator.com
Replace@mailinator with @tiscali.co.uk

> Hi,
>
[quoted text clipped - 19 lines]
>
> Wazza McG

Reply to this Message

Sandy Mann - 21 Nov 2005 00:35 GMT

Incidentally,

if as you say,

>> Now the hard bit, there are 16 Tablespoons and 48 teaspoons in a cup of
>> flour

surely there are three Teaspoons in a Tablespoon not four as you suggest in:

>> 3/4 C and 1C and so on. I know 5t should read 1T and 1t,

My formula returns 1 2/3C 0T 1t not 1 1/2C 2T 3t as you reckon, are you sure
about the relationship of cups, Tablespoon & teaspoons?

Also my formula returns 2C 0T 1t for 326g when 2C 0T 2t would be more
accurate but it is past 12:30am and I am work ing in the morning...

Signature

Regards
Sandy
sandymann@mailinator.com
Replace@mailinator with @tiscali.co.uk

>I created a VLOOKUP table like:
>
[quoted text clipped - 53 lines]
>>
>> Wazza McG

Reply to this Message

Mike G - 21 Nov 2005 02:22 GMT

Its my contention that 270g is 1 1/2 cups + 3 tablespoons.....no
teaspoons??? 160g=16T 10g=1T 270g-240g=30g 30g/10g=3T

> Hi,
>
[quoted text clipped - 19 lines]
>
> Wazza McG

Reply to this Message

Ron Rosenfeld - 21 Nov 2005 04:03 GMT

>Hi,
>
[quoted text clipped - 19 lines]
>
>Wazza McG

If you could eliminate those pesky 1/3 and 2/3 cup measures, it would be much
simpler (rounding Tsp to the nearest 1/4 tsp)

With the weight in A2:

Cups    B2:    =ROUNDDOWN(A2/160*4,0)/4
Tbsp    C2:    =INT((A2-(B2*160))/10)
Tsp    D2:    =ROUND((A2-B2*160-C2*10)/3*4,0)/4

If you insist on using those 1/3 and 2/3 cup measures, then the formula for
Cups becomes more complicated, as I believe you would want the most accurate
measure:

Cups    B2:

=MAX(ROUNDDOWN(A2/160*4,0)/4,ROUNDDOWN(A2/160*3,0)/
IF(ABS(A2-(ROUNDDOWN(A2/160*4,0)/4*160+INT((A2-(
ROUNDDOWN(A2/160*4,0)/4*160))/10)*10+ROUND((A2-
ROUNDDOWN(A2/160*4,0)/4*160-INT((A2-(ROUNDDOWN(
A2/160*4,0)/4*160))/10)*10)/3*4,0)/4*3))<ABS(A2-(ROUNDDOWN(
A2/160*3,0)/3*160+INT((A2-(ROUNDDOWN(A2/160*3,0)/3*160))
/10)*10+ROUND((A2-ROUNDDOWN(A2/160*3,0)/3*160-INT((A2-
(ROUNDDOWN(A2/160*3,0)/3*160))/10)*10)/3*4,0)/4*3)),30,3))

--ron

Reply to this Message

Wazza McG - 21 Nov 2005 08:33 GMT

Hi All,

Oh, I just researched the delemma and I now understand the argument
regarding the amount of teaspoons in a tablespoon due to the difference in
conversions between US, British, Canada and Australia measurements. This
site has a Standard Liquid Measurement -
http://www.ozevillage.com.au/gs/tips/gs.asp?topic=conversion .

a.. 5ml = 1/6fl oz = 1 teaspoon (50 teaspoons in 1 cup)
a.. 20ml = 2/3fl oz = 1 tablespoon (12.5 Tablespoons in 1 cup)
a.. 30ml = 1 fl oz = 1 tablespoon plus 2 teaspoons
a.. 60ml = 2fl oz = 1/4 cup
a.. 125ml = 4fl oz = 1/2 cup
a.. 185ml = 6fl oz = 3/4 cup
a.. 250ml = 8fl oz = 1 cup
a.. 500ml = 16fl oz = 2 cups
a.. 1 litre = 35fl oz = 4 cups

As you can see, I have made some corrections to my initial query.

I know the math in some of the conversions is not brilliant to say the
least, however, I am happy enough to use the above table. I agree with Ron
Rosenfeld - give the 1/3 and 2/3 of a Cup the flick.

I do own a metric scale, but, it is a real pain having to measure with it
all the time. This is the reason why, High Gluten Flour is 160g for 1 cup
and standard Flour is 120g for 1 cup. Sugar is 250g for 1 cup - the same as
water. I was hoping to measure 1 cup of an ingedient and then use that to
work out the imperial volume of random measurements eg ;
270g of sugar = 1C, 1T,0t ;
270g of High Gluten Flour is 1 C, 2T,1t.

Where 1C = 1 Cup, 1T = 1 Tablespoon and 1t = 1 teaspoon.

I know this is doosy of an equation, however, I am hoping there is an excel
guru out there that can shine some light on this.

Regards,

Wazza McG

>>Hi,
>>
[quoted text clipped - 49 lines]
>
> --ron

Reply to this Message

Wazza McG - 21 Nov 2005 08:40 GMT

Correction - 270g of High Gluten Flour = 1 1/2C, 2T, 1t

> Hi All,
>
[quoted text clipped - 92 lines]
>>
>> --ron

Reply to this Message

Ron Rosenfeld - 21 Nov 2005 12:16 GMT

The same basic formulas that I posted can be used. But since you are changing
the number of grams per cup depending on the substance, you'll need to change
those equivalents in a table.

The rewritten formulas (eliminating the 1/3 cups)

A2:        Weight in grams
B2 Cups:    =ROUNDDOWN(A2/GmPerCup*4,0)/4
C2 Tbsp:    =INT((A2-(B2*GmPerCup))/GmPerTbsp)
D2 Tsp:    =ROUND((A2-B2*GmPerCup-C2*GmPerTbsp)/GmPerTsp*4,0)/4

GmPerCup:    160 or whatever
GmPerTbsp:    =GmPerCup/12.5
GmPerTsp:    =GmPerCup/50

Using these formulas, and taking 270 gm @ 160 gm/cup, I get

1.5C    2T    1.5t

That is rounding 't' to the nearest 1/4 tsp (since I have a 1/4 tsp measure).
It actually calculates to 1.375t

You could also use a lookup table to insert the GmPerCup.

Have a column with the substance and a table with the conversions:

Table H1:K4 And the values for GmPerTbsp and GmPerTsp were generated by the
same formulas above.

Substance    HiGFlour    StdFlour    Sugar
GmPerCup    160        120        260
GmPerTbsp    12.8        9.6        20.8
GmPerTsp    3.2        2.4        5.2

Then set up the following:

A1:    Substance
B1:    Cups
C1:    Tbsp
D1:    Tsp

A2:    e.g. HiGFlour
B2:    e.g. 270
C2:    =ROUNDDOWN(B2/HLOOKUP(A2,$H$1:$K$4,2,FALSE)*4,0)/4
D2:
=INT((B2-(C2*HLOOKUP(A2,$H$1:$K$4,2,FALSE)))/HLOOKUP(A2,$H$1:$K$4,3,FALSE))

E2:
=ROUND((B2-C2*HLOOKUP(A2,$H$1:$K$4,2,FALSE)-
D2*HLOOKUP(A2,$H$1:$K$4,3,FALSE))/HLOOKUP(
A2,$H$1:$K$4,4,FALSE)*4,0)/4

Best,
--ron

>Hi All,
>
[quoted text clipped - 90 lines]
>>
>> --ron

--ron

Reply to this Message

Mike G - 21 Nov 2005 15:28 GMT

With all the corrections, I am staying out of the kitchen!! Mike

> The same basic formulas that I posted can be used. But since you are
> changing
[quoted text clipped - 159 lines]
>
> --ron

Reply to this Message

Ron Rosenfeld - 21 Nov 2005 15:33 GMT

>With all the corrections, I am staying out of the kitchen!! Mike

Well I'm no cook -- just a wannabee chemist :-))

--ron

Reply to this Message

Wazza McG - 21 Nov 2005 20:56 GMT

Ron,

I can not seem to replicate your spreadsheet - any chance of you sending it
to my email address by taking the "NoSpam" out of my address? By the way,
do you like pizza's?

Thank you Guru Swami,

Wazza McG

> The same basic formulas that I posted can be used. But since you are
> changing
[quoted text clipped - 159 lines]
>
> --ron

Reply to this Message