I think the best way to try and do it is as follows

write a marco as follows:

'----------------------------
Sub updatestockvalues()

   Const sheetNameQ As String = "Quotes"
   Const sheetNameDB As String = "Database"
   
   Const QcolumnName As String = "A"
   Const QcolumnValue As String = "C"
   Const QrowStart As Long = 2
   Const QtextTotal As String = "Total"
   
   Const DBcolumnDate As String = "A"
   Const DBcolumnValue As String = "B"
   Const DBrowStart As Long = 2 ' not the titles
   
   Dim Amt As Currency
   
   Dim r As Long ' row pointer
   Dim c As Long ' column number
   
   Dim wsQ As Worksheet, wsDB As Worksheet
   Set wsQ = ThisWorkbook.Sheets(sheetNameQ)
   
  ' insert the macro to run the quotes here.

   ' find total row in Quotes
   r = QrowStart
   Do While wsQ.Range(QcolumnName & r) <> QtextTotal
       r = r + 1
       If r = 65537 Then
           MsgBox "Error finding total, halting.", vbOKCancel, "Error"
           Set wsQ = Nothing
           Exit Sub
       End If
   Loop
       
   Amt = wsQ.Range(QcolumnValue & r).Value
   Set wsQ = Nothing
       
   Set wsDB = ThisWorkbook.Sheets(sheetNameDB)
   
   ' find last day in Database assume that there is at least one date
   r = DBrowStart
   Do While wsDB.Range(DBcolumnDate & r) <> ""
       r = r + 1
       If r = 65537 Then
           MsgBox "Error in database sheet, halting.", vbOKCancel, "Error"
           Set wsDB = Nothing
           Exit Sub
       End If
   Loop
   If (wsDB.Range(DBcolumnDate & r - 1) = Date) Then
       r = r - 1 ' date already there
   Else
       wsDB.Range(DBcolumnDate & r) = Date
   End If
   With wsDB.Range(DBcolumnValue & r)
       .Value = Amt
       .NumberFormat = "#,##0.00"
   End With
   Set wsDB = Nothing
   
End Sub
'----------------------------

This will update the sheet with the new day or current value.
You may have to play around with the dates if they are not dates in the
database but text.

You now need to get the name of the macro that is called when you click the
update quotes button and insert it into the macro above at the place where
indicated to insert the macro and then instead of clicking the current button
you click a new button that you need to asign to the above code.

I don't have the msquotes program so I can't advise.

I may be able to look at it if you give me a link to it.

This should set you on your way.