That's not a problem caused by formulas or values.

That's a problem with the way excel works with long strings in cells.  You can
do a small test in a test workbook to see that using formulas works ok when
edit|replace (no long strings, though).

And you could use a macro that tries to do an edit|Replace and for all the cells
that this fails on, the macro can do the work on a cell-by-cell basis:

(Saved from a previous post)

You can use a macro to do the change:

Option Explicit
Sub testme01()

   Dim FoundCell As Range
   Dim ConstCells As Range
   Dim BeforeStr As String
   Dim AfterStr As String

   BeforeStr = "$$$$$"
   AfterStr = " "  'or chr(10) 'for alt-enter

   With ActiveSheet
       Set ConstCells = Nothing
       On Error Resume Next
       Set ConstCells = .Cells.SpecialCells(xlCellTypeConstants, _
                                                         xlTextValues)
       On Error GoTo 0

       If ConstCells Is Nothing Then
           MsgBox "Select some cells in the used range"
           Exit Sub
       End If

       With ConstCells
           'get as many as we can in one step
           .Replace what:=BeforeStr, Replacement:=AfterStr, _
                       lookat:=xlPart, SearchOrder:=xlByRows

           Do
               Set FoundCell = .Cells.Find(what:=BeforeStr, _
                                   after:=.Cells(1), _
                                   LookIn:=xlValues, _
                                   lookat:=xlPart, _
                                   SearchOrder:=xlByRows, _
                                   searchdirection:=xlNext, _
                                   MatchCase:=False)

               If FoundCell Is Nothing Then
                   'done, get out!
                   Exit Do
               End If
               FoundCell.Value _
                   = Replace(FoundCell.Value, BeforeStr, AfterStr)
           Loop
       End With
   End With
End Sub

If you're using xl97, change that Replace() to application.substitute()

If you're new to macros, you may want to read David McRitchie's intro at:
http://www.mvps.org/dmcritchie/excel/getstarted.htm

Ps. Try it against a copy of your data--just in case!