One guess is that you're hinting at using Solver (under Tools > Solver)

I don't know of any such function, but you could put together a UDF to
do this for you.  I also don't understand your second requirement; no
value between 3.99 and 5.09 will return a value less than 15.26% when
divided by 2.35.  However, here's a function that will take any number
of arguments as string, each beginning with either a < or a >, and
generate a random number within the specified parameters.  So, you
would use it in a worksheet like so:

=ROUND(myFunction(">2.35","<5.09","<5.25","<=5.09",">3.99"), 2)

This is the code, to be placed in a standard module:

Public Function myFunction(ParamArray vals() As Variant) As Variant
 On Error GoTo errorExit

 Application.Volatile
 Const incr As Long = 5

 Dim smallest() As Double
 Dim largest() As Double

 Dim iSize As Long
 Dim jSize As Long

 Dim d As Double

 Dim i As Long, j As Long
 Dim k As Long

 iSize = incr
 ReDim smallest(1 To iSize)
 jSize = incr
 ReDim largest(1 To jSize)

 For k = LBound(vals) To UBound(vals)
   If Left$(vals(k), 1) = ">" Then
     i = i + 1
     If (i > iSize) Then
       iSize = iSize + incr
       ReDim Preserve smallest(1 To iSize)
     End If
     If Mid$(vals(k), 2, 1) <> "=" Then
       d = CDbl(Right$(vals(k), Len(vals(k)) - 1))
     Else
       d = CDbl(Right$(vals(k), Len(vals(k)) - 2))
     End If
     smallest(i) = d
   ElseIf (Left$(vals(k), 1) = "<") Then
     j = j + 1
     If (j > jSize) Then
       jSize = jSize + incr
       ReDim Preserve largest(1 To jSize)
     End If
     If Mid$(vals(k), 2, 1) <> "=" Then
       d = CDbl(Right$(vals(k), Len(vals(k)) - 1))
     Else
       d = CDbl(Right$(vals(k), Len(vals(k)) - 2))
     End If

     largest(j) = d
   Else
     Err.Raise (3333)
   End If
 Next k

 If (i < iSize) Then
   ReDim Preserve smallest(1 To i)
 End If

 If (j < jSize) Then
   ReDim Preserve largest(1 To j)
 End If

 With Application.WorksheetFunction
   If (.Max(smallest) > .Min(largest)) Then
     Err.Raise (3333)
   Else
     myFunction = Rnd() * (.Min(largest) - .Max(smallest))
+ .Max(smallest)
   End If
 End With
 Exit Function

errorExit:
 myFunction = CVErr(XlCVError.xlErrValue)
 Exit Function
End Function

Suggest you restate your question with examples.

Tyro