We need a little more information... what do you want to happen when
multiple words occur without an intervening number? For example, how did you
want the words "special occasion" from your example handled... "special" in
one cell, "occasion" in another, or both in one cell? If both in one cell,
will that be the case if multiple words occur somewhere other than at the
end of the text?

Rick

Here's a routine that might work if I understand your pattern correctly.

<alt-F11> opens the VB Editor.  Ensure your project is highlighted in the
Project Explorer window, then Insert/Module and paste the code below into the
window that opens.

Be sure to define Dest and Src appropriately in the VBA Code.

Then <alt-F8> opens the macro dialog box.  Select the macro and <Run>.

The logic is (or should be <g>), that the routine views the data as a sequence
of words.

It looks for sub-sequences which consist of a word that consists only of
digits, followed by a sequence of words none of which consist of only digits.

It then splits them.

That should take care of issues such as multiple word descriptors, as you have
with "special occasion", as well as descriptors that might include a digit.

But this should give you a start, and you can post back with how it works.

=================================================
Option Explicit
Sub ParseData()
Dim Src As Range
Dim Dest As Range
Dim c As Range
Dim i As Long, j As Long
Dim re As Object, mc As Object, m As Object
Const sPat As String = "(\d+)\s+(.*?)(?=(\b\d+\b)|$)"

Set Src = Range("A3:a100") 'or wherever your data is
Set Dest = Range("H3:H100") 'your destination range

Dest.ClearContents
Set re = CreateObject("vbscript.regexp")
   re.Global = True
   re.Pattern = sPat
j = 1
For Each c In Src
   If re.test(c.Text) = True Then
       Set mc = re.Execute(c.Text)
           For i = 0 To mc.Count - 1
               Dest(j, i * 2 + 1).Value = mc(i).submatches(0)
               Dest(j, i * 2 + 2).Value = mc(i).submatches(1)
           Next i
   End If
j = j + 1
Next c
End Sub
=============================================
--ron