Joe,

I've found a solution, but it's not pretty.  I turned your spreadsheet
upside down, then I added two "helper" columns which will tell you when a
"reset" occurs (someone takes 34 hours off).

B3 to B33 numbered from 31 down to 1
C3 to C40 available to accept hours on duty for each day
D3 to D40 displays the number of hours worked in the last 7 days, OR since
the last "reset" (when 34 hours off occurred)
E3 to E40 the number of hors available to be on duty for the next day

Assuming people can be on duty for 24 hours in a day, then their clock
"resets" when they don't work for a whole day AND they didn't work more than
14 hours for the previous day.  Therefore, if you make column G a reset
indicator:
    G3=IF(AND(C3=0,C4<=14),"R","")
copied down to G40

Now, Add a second helper column, column H, which will tell you how many days
ago a reset occured, if it occurred within the last 7 days.
    H3=MATCH("R",G3:G10,0)
copied down to H40

Next, create column D (hours so far).  If column C is blank, enter ""
otherwise, calculate the answer.  To calculate the answer, you will see if
there was a reset in the last 7 days.  If there wasn't, you'll have a #N/A
value in column G.  So if there was no reset, just sum the last 7 days,
otherwise, sum the last H days (actually, row H counted today as the first
day, so we subtract 1 from the value in H).

D3=IF(ISBLANK(C3),"",IF(ISERROR(H3),SUM(C3:C9),SUM(OFFSET(C3,0,0,H3-1))))
and copy down to D33.  Change the formula slightly

D34=IF(ISBLANK(C34),"",IF(ISERROR(H34),SUM(C34:C$40),SUM(OFFSET(C34,0,0,H34-
1))))
and copy down to D40

Finally, create column E (hours available for tomorrow).  This is simple,
now, because column D is a running total of the last 7 days or since the
last reset, so simply subtract that from 70.
    E3=IF(ISBLANK(C3),"",70-D3)
and copy down to E40

Feel free to hide columns G and H, as they are ugly.

Trevor

PS - Note that your spreadsheet deals with whole days.  This can cause a
problem if someone is on duty for 14 hours from 10:00am to midnight on
Monday, but does not work at all on Tuesday.  As far as the spreadsheet is
concerned, they will have one empty day and the prior day will be 14 hours,
which does match the test that within those 2 days, there were 34 hours
during which they were not on duty.  So the spreadsheet resets their clock.
When in reality, the person was not off duty for a 34-hour block.  You'll
need to change to tracking by the hour, instead of the day, if you want to
be accurate.