Ron,

Put your list into column A of one sheet.  On another sheet, starting in Cell A1 and going across
Row 1, put the identifiers for the data that you want to extract/remove from your datatable:

ID # :
Sex :
Raw Scores :
T Scores :

These whould be entered into A1, B1, C1, D1. Note the inclusion of the colon.

Then select those cells (you can have as many as you want, as long as the strings appear within your
database) and name them "Headers"  (Select them, then use Insert / Names...   Define...)

Then select your sheet with the database of values, and run the macro below.

If you cannot get it to work, I will send you a working example.

HTH,
Bernie
MS Excel MVP

Sub MakeDataBase()
Dim myData As Range
Dim myArea As Range
Dim myCell As Range
Dim i As Integer
Dim myRow As Long

myRow = 2

Set myData = ActiveSheet.Range("A:A"). _
  SpecialCells(xlCellTypeConstants, 2)

For Each myArea In myData.Areas
For Each myCell In myArea
For i = 1 To Range("Headers").Cells.Count
If InStr(1, myCell.Value, Range("Headers"). _
  Cells(1, i).Value) > 0 Then
 Range("Headers").Parent.Cells(myRow, i).Value = _
 Application.Trim(Replace(myCell.Value, _
 Range("Headers").Cells(1, i).Value, ""))
End If
Next i
Next myCell
myRow = myRow + 1
Next myArea

With Range("Headers").Parent
.Range("D:I").EntireColumn.Insert
.Range("C2", .Cells(Rows.Count, 3).End(xlUp)).TextToColumns _
  Destination:=.Range("C2"), _
  DataType:=xlDelimited, _
  ConsecutiveDelimiter:=True, _
  Space:=True
  .Range("C1:I1").Formula = "=""Raw Score "" & Column()-2"
  .Range("C1:I1").Value = .Range("C1:I1").Value

  .Range("J2", .Cells(Rows.Count, 10).End(xlUp)).TextToColumns _
  Destination:=.Range("J2"), _
  DataType:=xlDelimited, _
  ConsecutiveDelimiter:=True, _
  Space:=True
  .Range("J1:P1").Formula = "=""T Score "" & Column()-9"
  .Range("J1:P1").Value = .Range("J1:P1").Value
End With

End Sub