You can do this manually or by macro.

Manually select column A and F5>Special>Blanks>OK.

In activecell(the white one) type an  =  sign then point to the cell above.

CTRL + ENTER will fill the blanks with the value from above.

With column A still selected.....copy>paste special>values>OK>Esc.

Macro............

Sub Fill_Blanks()
'by Dave Peterson  2004-01-06
'fill blank cells in column with value above
Dim wks As Worksheet
Dim rng As Range
Dim lastrow As Long
Dim col As Long

   Set wks = ActiveSheet
   With wks
       col = ActiveCell.Column
   'or
   'col = .range("b1").column

       Set rng = .UsedRange        'try to reset the lastcell
       lastrow = .Cells.SpecialCells(xlCellTypeLastCell).Row
       Set rng = Nothing
       On Error Resume Next
       Set rng = .Range(.Cells(2, col), .Cells(lastrow, col)) _
               .Cells.SpecialCells(xlCellTypeBlanks)
       On Error GoTo 0

       If rng Is Nothing Then
           MsgBox "No blanks found"
           Exit Sub
       Else
            rng.NumberFormat = "General"
           rng.FormulaR1C1 = "=R[-1]C"
       End If

   'replace formulas with values
       With .Cells(1, col).EntireColumn
           .Value = .Value
       End With

   End With

End Sub

Gord Dibben  MS Excel MVP