Hi Phil,

To run the macro whenever the workbook is opened...

First, channge the original code as follows...

Sub ChangeChartBg(ByRef sht As Worksheet)
'
' ChangeChartBg
' 26-06-2007 by Ed Ferrero

Dim cht As Chart
Dim chtArea As ChartArea
Dim myPath As String
Dim myFile As String

' change the following line to refer to your chart
' here I assume you only have one chart on each sheet
' if there is more than one chart, either loop through
' each chart and change the background, or name the chart you wish
' to change and use Set cht = sht.ChartObjects("myChartName").Chart
' to change it
Set cht = sht.ChartObjects(1).Chart
Set chtArea = cht.ChartArea

' Change the following lines to refer to the picture you wish to see
' in this example cell F1 contains the file path
' and cell F2 contains the file name that you wish to use as background
myPath = sht.Range("$F$1").Value
myFile = sht.Range("$F$2").Value

   chtArea.Fill.UserPicture PictureFile:=myPath & myFile
   chtArea.Fill.Visible = True
End Sub

Then, add the following code to the code pane for the Workbook (double-click
Thisworkbook in the VB Editor) and copy the code.

Private Sub Workbook_Open()
Dim sht As Worksheet
 For Each sht In ThisWorkbook.Worksheets
   Call ChangeChartBg(sht)
 Next sht
End Sub

That's it. The Workbook_Open code runs whenever the workbook is opened. It
loops through each worksheet and calls the ChangeChartBg procedure. It
passes the worksheet object to the ChangeChartBg procedure, so that the
first chart on each sheet is updated.

Ed Ferrero