Asif,

A far as I know, it is not possible without using a macro.

The following macro code will print all of the pages on the active sheet.
It adds the page number to the right footer.  They are printed as... "Page ll of lll."

'---------------------------------------------------------
Sub DoItLikeTheRomans()
'Jim Cone July 11, 2004
Dim strRomanAll    As String
Dim strRomanEach   As String
Dim lngTotalPages  As Long
Dim lngPageToPrint As Long

'Find the total number of pages to print.
lngTotalPages = ExecuteExcel4Macro("get.document(50)")
'Convert the total number of pages to Roman.
strRomanAll = WorksheetFunction.Roman(lngTotalPages)

'Go thru each page on the sheet.
For lngPageToPrint = 1 To lngTotalPages
   'Convert each single page number to Roman.
    strRomanEach = WorksheetFunction.Roman(lngPageToPrint)
   'Insert the Roman text into the right footer.
    ActiveSheet.PageSetup.RightFooter = "Page " & strRomanEach & "  of  " & strRomanAll
   'Print the page.
    ActiveSheet.PrintOut lngPageToPrint, lngPageToPrint
Next 'page
End Sub
'---------------------------------------------------

Regards,
Jim Cone
San Francisco, CA