CAM, here is some code by Ron de Bruin and one from Tom Ogilvy that together
will do what you want, I think, just put it all in a module and run the
Print_And_Move sub. After you change the paths

Sub Print_And_Move()
PrintFiles
MoveFiles
End Sub

Private Sub PrintFiles()
'will print all excel files in C:\Data
'By: Ron de Bruin
Dim i As Long
   Dim WB As Workbook
   Application.ScreenUpdating = False
   With Application.FileSearch
       .NewSearch
       .LookIn = "C:\Data" '****Change path here*****
       .SearchSubFolders = False
       .FileType = msoFileTypeExcelWorkbooks
       If .Execute() > 0 Then
           For i = 1 To .FoundFiles.Count
            Set WB = Workbooks.Open(.FoundFiles(i))
            WB.PrintOut Copies:=2
            WB.Close False
           Next i
       End If
   End With
   Application.ScreenUpdating = True
End Sub

Private Sub MoveFiles()
'By: Tom Ogilvy
Dim filelist() As Variant
ReDim filelist(1 To 1)
Dim srcPath As String
Dim destPath As String
Dim sFile As String
Dim i As Long
srcPath = "C:\Data\"  '****Change path here*****
destPath = "C:\New Data\"  '****Change path here*****
sFile = Dir(srcPath & "*.xls")
Do While sFile <> ""
filelist(UBound(filelist)) = sFile
ReDim Preserve filelist(1 To UBound(filelist) + 1)
sFile = Dir
Loop
For i = 1 To UBound(filelist) - 1
Name srcPath & filelist(i) As destPath & filelist(i)
Next i
End Sub