You could import to Word and use the "columns" feature then export back to
Excel.

The solution in Excel alone would depend upon how you wanted the column lay out
to look like when complete.

Do you want the 3 column "snaked" into 6 columns or into sets of a given number.

Assuming 3 columns of 1500 rows...

Snaking would give you 1- 750 and 751-1500

Sets could be 1-50 and 51-100 then next grouping of 101-150 and 151-200

Following are two macros...first will snake...second will give sets of 50 with a
pagebreak between sets.

Public Sub Snake3to6()
Dim myRange As Range
Dim colsize As Long
Dim maxrow As Long
Const numgroup As Integer = 2
Const NUMCOLS As Integer = 6
   On Error GoTo fileerror
   colsize = Int((ActiveSheet.UsedRange.Rows.Count + _
           ((NUMCOLS - 1)) / NUMCOLS)) / numgroup
   MsgBox "Number of Rows to Move is: " & colsize
   Range("A1").Select
   With ActiveCell.Parent.UsedRange
       maxrow = .Cells(.Cells.Count).Row + 1
   End With
   ActiveCell.Parent.Cells(maxrow, ActiveCell.Column) _
           .End(xlUp).Offset(1, 0).Select
   Set myRange = Range(ActiveCell.Address & ":" _
           & ActiveCell.Offset(-colsize, (numgroup)).Address)
   myRange.Cut Destination:=ActiveSheet.Range("D1")
   Application.CutCopyMode = False
   Range("A1").Select

fileerror:
End Sub

Sub Move_Sets()
Dim iSource As Long
Dim iTarget As Long

   iSource = 1
   iTarget = 1

   Do
       Cells(iSource, "A").Resize(50, 3).Cut _
       Destination:=Cells(iTarget, "A")
       Cells(iSource + 50, "A").Resize(50, 3).Cut _
       Destination:=Cells(iTarget, "D")
     
       iSource = iSource + 100
       iTarget = iTarget + 50
       PageBreak = xlPageBreakManual
   Loop Until IsEmpty(Cells(iSource, "A").Value)

End Sub

Gord Dibben  MS Excel MVP