Try this, but see the notes below -

Sub Test()
Dim clrIdx As Long
Dim lgdLt As Single, lgdTp As Single
Dim cht As Chart, sr As Series, lgd As Legend
' following perhaps arguments passed to the routine
Dim nSrIdx As Long
Static bVis

   nSrIdx = 2    ' < change to suit
   bVis = Not bVis

   Set cht = ActiveChart

   With cht.SeriesCollection(nSrIdx)
       .Fill.Visible = bVis
       If bVis Then
           clrIdx = xlAutomatic
       Else
           clrIdx = xlNone
       End If
       .Border.ColorIndex = clrIdx

       On Error Resume Next
       '  will error if not a Line type
       .MarkerBackgroundColorIndex = clrIdx
       .MarkerForegroundColorIndex = clrIdx
       On Error GoTo 0
   End With

   If cht.HasLegend Then
       lgdLt = cht.Legend.Left
       lgdTp = cht.Legend.Top
   End If

' assumes single axis chart
' with all series charttype the same
' might want to disable screenupdating

   cht.HasLegend = False
   cht.HasLegend = True
   Set lgd = cht.Legend

' caters for other series perhaps not visible
   With cht.Legend
       For i = cht.SeriesCollection.Count To 1 Step -1
           With cht.SeriesCollection(i)
               If .Fill.Visible = msoFalse _
                       And .Border.ColorIndex = xlNone Then
                   lgd.LegendEntries(i).Delete
               End If
           End With
       Next
       If lgdLt Then
           .Left = lgdLt
           .Top = lgdTp
       End If
   End With

End Sub

The toggle Legend Entry code is only 'relatively' reliable for typical
charts with a single axis and all series' ChartType's the same. For other
types would require a lot more code to get it reasonably reliable.

If border (line) and marker colours are not default automatic, might want to
store the original colorindex's and replace with same instead of
xlAutomatic. Similarly for other Legend and Legendkey properties.

The example includes minimal error handling for testing, just for the
markers, would need more.

Regards,
Peter T