I bet it's a typo.

.List(.List - 1, 1) = cfamily.Offset(0, 1).Value
should be:
.List(.ListCount - 1, 1) = cfamily.Offset(0, 1).Value

(same with cVendor, too).

Just an aside.

You can change properties in the properties window for any of your controls--or
you can change the properties in code.

Sometimes, it's easier (for me anyway) to see what's going on by using code
exclusively.

I'd make sure the .columncount is 2 and the .rowsource is empty -- just in
case...

Option Explicit
Private Sub UserForm_Initialize()

   Dim cFamily As Range
   Dim cVendor As Range
   Dim ws As Worksheet
   Set ws = Worksheets("Lookuplists")
   
   With Me.CBOFamily
       .ColumnCount = 2
       .RowSource = ""
   End With
   
   With Me.CBOVendor
       .ColumnCount = 2
       .RowSource = ""
   End With
   
   For Each cFamily In ws.Range("familylists")
       With Me.CBOFamily
           .AddItem cFamily.Value
           .List(.ListCount - 1, 1) = cFamily.Offset(0, 1).Value
       End With
   Next cFamily
   
   For Each cVendor In ws.Range("vendorlists")
       With Me.CBOVendor
           .AddItem cVendor.Value
           .List(.ListCount - 1, 1) = cVendor.Offset(0, 1).Value
       End With
   Next cVendor
   
   Me.TxtDenomination.Value = ""
   Me.TxtQuantity.Value = ""

End Sub

If you still have trouble adding the values to the combobox, you may be trying
to add errors (#value's, div/0, #ref's) to the combobox list.  .Value will fail
for those.

You could avoid them using
if iserror(cfamily.value) then
 'do something
...

Or you could just add the .Text to the combobox.  .Text is nice when you know
that your dates/times/quantities are formatted in the worksheet cell nicely.