I added some test code into your program to make it easier to find where the
problem is.   This way you don't have to step through the loop 500 times.  
You can change the $C$5 to any cell in the range to help find out where the
code is stopping.

With Worksheets(1).Range("a1:a500")
   Set c = .Find("Stop", LookIn:=xlValues)
   If Not c Is Nothing Then
       firstAddress = c.Address
       Do
'add test code to determine where the problem is
if c.address = "$C$5" then
  a = 1  'add break point here
end if

           c.Interior.ColorIndex = 3
           Set c = .FindNext(c)
       Loop While Not c Is Nothing And c.Address <> firstAddress
   End If
End With

When you use find you need to define most of the parameters of the find
operation as the end user has the ability to change these parameters which
persist. Generally speaking your code is fine otherwise. Were you intending
to do some deleting. If so then here is some code for you to try...

Sub FindStuff()
   Dim rngToSearch As Range
   Dim rngFound As Range
   Dim rngFoundAll As Range
   Dim strFirstAddress As String
   
   Set rngToSearch = Worksheets(1).Range("A1:A500")
   Set rngFound = rngToSearch.Find(What:="stop", _
                                   LookAt:=xlPart, _
                                   LookIn:=xlFormulas, _
                                   MatchCase:=False)
   If Not rngFound Is Nothing Then
       Set rngFoundAll = rngFound
       strFirstAddress = rngFound.Address
       Do
           Set rngFoundAll = Union(rngFound, rngFoundAll)
           Set rngFound = rngToSearch.FindNext(rngFound)
       Loop Until rngFound.Address = strFirstAddress
       With rngFoundAll
       .Select 'You will probably want to comment this line out
       .Interior.ColorIndex = 3
       '.EntireRow.Delete
       End With
   End If

End Sub