This is an interesting macro.  It puts the countif function into yoiur
worksheet automatically.  Just select the upper left hand cell in the range
of grades.  The macro look for the first empty column and adds the number of
A's in the row (will vary depending on number of grades in the row).  Then
moves over one row and does B's, then C's, and then D's.  It repeats this for
all rows until it finds the first empty row.

Sub count_results()

Set topleft = ActiveCell
Lastrow = topleft.End(xlDown).Row
LastColumn = topleft.End(xlToRight).Column
ColumnA = LastColumn + 1
For RowCount = topleft.Row To Lastrow
  For Columnoffset = 0 To 3
     Select Case Columnoffset
        Case 0
           Grade = """A"""
        Case 1
           Grade = """B"""
        Case 2
           Grade = """C"""
        Case 3
           Grade = """D"""
     End Select
     Formula = "=Countif(R" & RowCount & "C" & topleft.Column & _
        ":R" & RowCount & "C" & LastColumn & "," & Grade & ")"
     Cells(RowCount, ColumnA + Columnoffset).FormulaR1C1 = Formula
  Next Columnoffset
Next RowCount
End Sub

"Is there any macro...?"  There is now!

The macro below will do what you want.  You could even expand it later to
permit more answer options - it's set for 4 options now in array
possibleAnswers().

Press [Alt]+[F11] to open the VB Editor, choose Insert | Module and copy and
paste the code into the module presented.  Choose the sheet with the student
answer entries in it, and use Tools | Macro | Macros to run the macro.  It
presumes that NO percentages have been calculated for any row when you run it.
Also presumes that QID is in column A and all that follow it on a row are
answers entered by students when it begins.

Sub CalcResults()
'must start with QID and answer inputs ONLY
'you'll need to clear any previous entries
'on ALL rows before using this
'
'you must have the data sheet selected
'before running this Macro
'
 Const firstAnswerRow = 2 ' first row # with question data
 Dim possibleAnswers(1 To 4) As String
 Dim resultsChosenCounts() As Long
 Dim lastRow As Long
 Dim lastCol As Long
 Dim maxColumns As Long
 Dim baseCell As Range
 Dim rOffset As Long
 Dim cOffset As Long
 Dim numEntries As Long
 Dim selectionCount As Long
 Dim ALC As Integer ' array loop counter
 
'initialize possibleAnswers() array
 possibleAnswers(1) = "a" ' case is not important
 possibleAnswers(2) = "b"
 possibleAnswers(3) = "c"
 possibleAnswers(4) = "d"
 ReDim resultsChosenCounts(LBound(possibleAnswers) To _
  UBound(possibleAnswers)) ' dimensions must match
 If Val(Left(Application.Version, 2)) < 12 Then
   'in Excel 2003 or earlier
   lastRow = Range("A" & Rows.Count).End(xlUp).Row
   maxColumns = Columns.Count
 Else
   'in Excel 2007 (or later)
   lastRow = Range("A" & Rows.CountLarge).End(xlUp).Row
   maxColumns = Columns.Count
 End If
 If lastRow < firstAnswerRow Then
   Exit Sub ' no question data entered
 End If
 Set baseCell = ActiveSheet.Range("A" & firstAnswerRow)
 'start looping through used rows
 Do Until rOffset + baseCell.Row > lastRow
   lastCol = baseCell.Offset(rOffset, 0).End(xlToRight).Column
   numEntries = lastCol - 1 ' assumes all are question results
   If lastCol > (maxColumns - UBound(resultsChosenCounts)) Then
     MsgBox "Not Enough Columns to Present all Results.", _
      vbOKOnly, "Aborting"
     Set baseCell = Nothing
     Exit Sub
   End If
   'reset/initialize
   selectionCount = 0
   cOffset = 1 ' start looking in Col B
   For ALC = LBound(resultsChosenCounts) To _
    UBound(resultsChosenCounts)
     resultsChosenCounts(ALC) = 0 ' reset
   Next
   For ALC = LBound(possibleAnswers) To UBound(possibleAnswers)
     For cOffset = 1 To lastCol - 1
       If UCase(Trim(baseCell.Offset(rOffset, cOffset))) = _
        UCase(Trim(possibleAnswers(ALC))) Then
         resultsChosenCounts(ALC) = resultsChosenCounts(ALC) + 1
       End If
     Next
   Next ' end ALC loop
   For ALC = LBound(resultsChosenCounts) To _
    UBound(resultsChosenCounts)
     baseCell.Offset(rOffset, (lastCol - 1) + ALC) = _
      resultsChosenCounts(ALC) / numEntries
     baseCell.Offset(rOffset, (lastCol - 1) + ALC).Style = _
      "Percent"
   Next ' end ALC output loop
   rOffset = rOffset + 1 ' move to next row
 Loop ' row loop
End Sub