OK,

Here's the first version.  Please try this on a copy of your
workbooks, if you have a chance.  Paste the into a standard module
(does not have to be ALL Trend Log), and adjust the paths
accordingly.  I'll come up with some test data that meet your criteria
and post back a final version with any corrections and error handling
code.

-Ilia

'begin code
Option Explicit

Public Sub lookForFiles()
 Const strRunsPath As String = "C:\E2APBBX\"
 Const strTrendPath As String = "C:\Quant. Assay Trend Logs\"
 Const strTrendFileName As String = "ALL Trend Log.xls"
 Const strWshName As String = "E2APBX"
 Const strDataRange As String = "B1,D1,F4,D4,E4,K4,I4,J4,K1"

 Dim currFileName As String

 Dim wshTemp As Excel.Worksheet
 Dim wkbTrend As Excel.Workbook
 Dim wshTrend As Excel.Worksheet
 Dim iFileCount As Long

 Dim wkbData As Excel.Workbook
 Dim wshData As Excel.Worksheet
 Dim rngData As Excel.Range

 Dim iCellCount As Long

 Dim firstNewRow As Long
 Dim iCurrFile As Long

 Dim lastDate As Date

 Application.ScreenUpdating = False

 If ThisWorkbook.Name = strTrendFileName Then
   Set wkbTrend = ThisWorkbook
 Else
   Set wkbTrend = _
     Application.Workbooks.Open(strTrendPath & _
                                 strTrendFileName)
 End If

 ' add a temporary sheet to keep track of new data files
 Set wshTrend = wkbTrend.Worksheets(strWshName)
 Set wshTemp = wkbTrend.Worksheets.Add
 wshTemp.Visible = xlSheetVeryHidden

 ' get the latest date of last run entered
 lastDate = getLastDate(wshTrend)

 ' look for new files
 currFileName = Dir(strRunsPath)
 With wshTemp
   Do While currFileName <> ""
     If (fileNameMatches(currFileName) And _
         extractRunDate(currFileName) > lastDate) Then
       iFileCount = iFileCount + 1
       .Cells(iFileCount, 1).Value = currFileName
     End If
     currFileName = Dir()
   Loop

   firstNewRow = getFirstNewRow(wshTrend)
   For iCurrFile = 1 To iFileCount
     ' open each new file
     Set wkbData = _
         Application.Workbooks.Open(strRunsPath & _
                                   .Cells(iCurrFile, 1))
     Set wshData = wkbData.Worksheets("Sheet 1")

     ' process all cells in range
     iCellCount = 0
     For Each rngData In wshData.Range(strDataRange)
       iCellCount = iCellCount + 1
       wshTrend.Cells(firstNewRow, _
                   iCellCount).Value = rngData.Value
       firstNewRow = firstNewRow + 1
     Next rngData
     wkbData.Close (False)
   Next iCurrFile

   Application.DisplayAlerts = False
   .Delete
   Application.DisplayAlerts = True
 End With

 Application.ScreenUpdating = True
End Sub

Private Function getFirstNewRow(ByRef wsh As _
                         Excel.Worksheet) As Long
 Dim iCount As Long
 Dim firstNewRow As Long

 firstNewRow = wsh.UsedRange.Rows.Count + 1

 ' leave 3 rows blank every 15 rows
 For iCount = 21 To firstNewRow Step 15
   If firstNewRow = iCount Then
     firstNewRow = firstNewRow + 3
   ElseIf (firstNewRow = iCount + 1) Then
     firstNewRow = firstNewRow + 2
   ElseIf (firstNewRow = iCount + 2) Then
     firstNewRow = firstNewRow + 1
   End If
 Next iCount

 getFirstNewRow = firstNewRow
End Function

Private Function getLastDate(ByRef wsh As _
                       Excel.Worksheet) As Date
 ' using a separate function for this
 ' in case we need to use a cell-by-cell
 ' algorithm to find latest date, instead of Max
 getLastDate = _
     Application.WorksheetFunction.Max( _
                           wsh.Range("$B:$B"))
End Function

Private Function fileNameMatches(fileName As String) _
                                         As Boolean
 ' file name must start with E2APBX
 ' run # may be anywhere from 1 to 9999999
 ' initials may be 2 or 3 characters
 ' date must be m-d-yy format
 ' 01-01-07 is invalid because of leading zeroes
 ' file extension must be .xls, .xlsx, or .xlsm
 Const strPattern As String = _
   "^E2APBX" & _
   "[1-9][0-9]{0,6}" & _
   "[A-Z]{2,3}" & _
   "[1-9][012]{0,1}-[1-9][0-9]{0,1}-[0-9][0-9]" & _
   "[.]xls[xm]{0,1}$"

 'VBScript_RegExp_10.RegExp
 Dim objRegExp As Object

 'New VBScript_RegExp_10.RegExp
 Set objRegExp = CreateObject("vbscript.RegExp")

 With objRegExp
   .Pattern = strPattern
   .IgnoreCase = True
   fileNameMatches = .test(fileName)
 End With
End Function

Private Function extractRunDate(fileName As String) _
                                           As Date
 ' sample file name: "E2APBX1897DV6-13-07.xls"

 Dim iDateBegins As Integer
 Dim iDateEnds As Integer

 Dim iPointer As Integer

 iDateEnds = InStrRev(fileName, ".") - 1
 iDateBegins = InStr(fileName, "-") - 2
 If Not isDigit(Mid(fileName, iDateBegins, 1)) Then
   iDateBegins = iDateBegins + 1
 End If

 extractRunDate = Mid(fileName, iDateBegins, _
                             iDateEnds - iDateBegins)
End Function

Private Function isDigit(dig As String) As Boolean
 isDigit = (Asc(dig) >= Asc(0) And Asc(dig) <= Asc(9))
End Function
' end code