hi,
i don't have 2007. 2002 here. but the RGB equivilent to the button color is
RGB(220,220,220). how you would adjust that in 2007, i don't know.
in 2002, i adust the colors using the RGB scale.

regards
FSt1

The function can accept values 0 to 40 (don't think any system has that many
system colours) or system color constants from
-2147483608 to -2147483648

The two test procedures will customize the palette, so run in a new workbook

Public Declare Function GetSysColor Lib "user32" ( _
                                   ByVal nIndex As Long) As Long

Function fnSysClr(ByVal nSysClr As Long) As Long
Dim lngColor As Long

   If nSysClr < -2 ^ 31 + 40 Then
       nSysClr = 2 ^ 31 + nSysClr
   End If

   If nSysClr >= 0 And nSysClr < 40 Then
       fnSysClr = GetSysColor(nSysClr)
   End If

End Function

Sub test1()
Dim nClr As Long, x&

   x = vbActiveTitleBar
'     x = vbButtonFace
   nClr = fnSysClr(x)

   With ActiveCell.Interior
       .Color = nClr
       ' did the colour alread exist in the palette or was
       ' only the nearest colour applied
       If .Color <> nClr Then
           ' customize a palette colour and reapply
           ActiveWorkbook.Colors(49) = nClr
           .ColorIndex = 49
       Else
           Debug.Print .ColorIndex
       End If
   End With

End Sub

Sub test2()
Dim i As Long
Dim nClr As Long
For i = 0 To 39    ' probably exceeds no. of system colours
   nClr = fnSysClr(i)
   If nClr >= 0 And nClr <= 17666215 Then
       ActiveWorkbook.Colors(i + 16 + 1) = nClr
       Cells(i + 1, 1).Interior.ColorIndex = i + 16
       Cells(i + 1, 2) = i
       Cells(i + 1, 3) = i - 2 ^ 31
   End If
Next
Range("B:C").Columns.AutoFit

End Sub

Regards,
Peter T