Two quick comments...

First, you should put these lines...

           Application.Calculation = xlCalculationAutomatic
           Application.EnableEvents = True
           Application.ScreenUpdating = True
           Application.StatusBar = False

in the Finished error handler, otherwise they won't get turned back in if an
error occurs.

Second, you can't check the Err.Number after you execute On Error GoTo 0 as
it will be 0.

Rick

There's a lot of "more code", but this untested, uncompiled code may be closer:

Option Explicit
Sub GetTenantInfo()

   Dim wbkCopyFrom As Workbook
   Dim wbkCopyFromName As String
   Dim wbkCopyTo As Workbook
   Dim FromwbkPath As Variant 'I like to see "As Variant"
   Dim ShName As String
   Dim CopyWSError As Boolean
 
   CopyWSError = False
   Set wbkCopyTo = ThisWorkbook
   
   FromwbkPath = Application.GetOpenFilename(Filefilter:="Excel Files, *.xls")
   If FromwbkPath = False Then
       Exit Sub 'user hit cancel
   End If
   
   'just the filename
   wbkCopyFromName = Mid(FromwbkPath, InStrRev(FromwbkPath, "\") + 1)
       
   On Error Resume Next
   'you don't use the whole path--just the filename here
   Set wbkCopyFrom = Workbooks(wbkCopyFromName)
   On Error GoTo 0
   
   If wbkCopyFrom Is Nothing Then
       On Error Resume Next
       Set wbkCopyFrom = Workbooks.Open(Filename:=FromwbkPath)
       On Error GoTo 0
       If wbkCopyFrom Is Nothing Then
           MsgBox "Cannot Open originating file--in use or wrong password?"
           Exit Sub
       Else
           Application.StatusBar = "Processing. Please Wait."
           Application.ScreenUpdating = False
           Application.EnableEvents = False
           Application.Calculation = xlCalculationManual

           'My Code
           
           'copy the sheet
           Call AddSheets.UnProtectWkbook
           
           On Error Resume Next
           CAMMaster.Copy After:=Sheets(ShNumber)
           If Err.Number <> 0 Then
               Err.Clear
               CopyWSError = True
               GoTo Finished
           Else
               'no error occurred
           End If
           On Error goto 0
           
           'name the sheet
           ActiveSheet.Name = ShName
           Call ProtectSht(ShName)
           Call AddSheets.ProtectWkbook
           
           More Code
           
           wbkCopyTo.Save
                             
       End If
   End If
   
Finished:

   If CopyWSError = True Then
       wbkCopyTo.Save  'save it even if there was an error?????
       MsgBox "Maximum tenant sheets copied." & vbLf _
                & "Close workbook, reopen and restart 'Recreate Tenant Sheets'"
   End If

   Application.Calculation = xlCalculationAutomatic
   Application.EnableEvents = True
   Application.ScreenUpdating = True
   Application.StatusBar = False
   
End Sub