You are welcome. I have to apologize to you though... I meant to put the
worksheet names in section you fill in so you wouldn't have had to search
for them in the actual code. In case you (or other readers of this thread)
might find it useful, here is that code (with it, you only have to change
values in the marked-off section and nowhere else) ...

Sub ConsolidateData()
 Dim CurrentID As String
 Dim LastCellInRow As Long
 Dim DataHeaderRow As Long
 Dim ReportHeaderRow As Long

 ' *********************************************
 ' * Set your worksheet values in this section *
 ' *********************************************
 Const DataSheetName = "Data"
 Const DataIDCol = "A"
 Const DataCountryCol = "B"
 Const DataNumberCol = "C"
 DataHeaderRow = 1           '0 if no header
 Const ReportSheetName = "Report"
 Const ReportIDCol = "A"
 Const ReportRelatedMattersCol = "B"
 ReportHeaderRow = 1         '0 if no header
 ' *********************************************

 With Worksheets(DataSheetName)
   CurrentID = .Cells(2, DataIDCol).Value
   LastCellInRow = .Cells(.Rows.Count, DataIDCol).End(xlUp).Row
   Do While DataHeaderRow <= LastCellInRow
     DataHeaderRow = DataHeaderRow + 1
     If .Cells(DataHeaderRow, DataIDCol).Value <> "" Then
       ReportHeaderRow = ReportHeaderRow + 1
       CurrentID = .Cells(DataHeaderRow, DataIDCol).Value
       Worksheets(ReportSheetName).Cells(ReportHeaderRow, _
                   ReportIDCol).Value = CurrentID
       Worksheets(ReportSheetName).Cells(ReportHeaderRow, _
                   ReportRelatedMattersCol).Value = _
                   .Cells(DataHeaderRow, DataCountryCol).Value & " " & _
                   .Cells(DataHeaderRow, DataNumberCol).Value
     Else
       Worksheets(ReportSheetName).Cells(ReportHeaderRow, _
                   ReportRelatedMattersCol).Value = _
                   Worksheets(ReportSheetName).Cells(ReportHeaderRow, _
                   ReportRelatedMattersCol).Value & "; " & _
                   .Cells(DataHeaderRow, DataCountryCol).Value & " " & _
                   .Cells(DataHeaderRow, DataNumberCol).Value
     End If
     If DataHeaderRow = LastCellInRow Then Exit Do
   Loop
 End With
End Sub

Rick