Something like this should do...

Sub CopyStuff()  'Run Me
   Dim rngCopy As Range
   Static rngPaste As Range
   
   Set rngCopy = Range("B1:N1")
   If rngPaste Is Nothing Then
       Set rngPaste = LastCell
       Set rngPaste = Range(Cells(rngPaste.Row, "B"), Cells(rngPaste.Row,
"N"))
   End If
   Set rngPaste = rngPaste.Offset(1, 0)
   rngPaste.Value = rngCopy.Value
   rngCopy.ClearContents
End Sub

Public Function LastCell(Optional ByVal wks As Worksheet) As Range
   Dim lngLastRow As Long
   Dim intLastColumn As Integer
   
   If wks Is Nothing Then Set wks = ActiveSheet
   On Error Resume Next
   lngLastRow = wks.Cells.Find(What:="*", _
                           After:=wks.Range("A1"), _
                           Lookat:=xlPart, _
                           LookIn:=xlFormulas, _
                           SearchOrder:=xlByRows, _
                           SearchDirection:=xlPrevious, _
                           MatchCase:=False).Row
   intLastColumn = wks.Cells.Find(What:="*", _
                           After:=wks.Range("A1"), _
                           Lookat:=xlPart, _
                           LookIn:=xlFormulas, _
                           SearchOrder:=xlByColumns, _
                           SearchDirection:=xlPrevious, _
                           MatchCase:=False).Column
   On Error GoTo 0
   If lngLastRow = 0 Then
       lngLastRow = 1
       intLastColumn = 1
   End If
   Set LastCell = wks.Cells(lngLastRow, intLastColumn)
   
End Function

try this
Sub Moverow()
lr = Cells(Rows.Count, "b").End(xlUp).Row + 1
With Range(Cells(1, "b"), Cells(1, "bn"))
.Copy Cells(lr, "b")
.ClearContents
End With
End Sub