Hi Raj,

In the worksheet's code module replace
your existing Workshhet_Change code
with the following version:

'==========>>
Option Explicit

Private Sub Worksheet_Change( _
               ByVal Target As Range)
   Dim Rng As Range
   Dim rcell As Range
   Const sCol As String = "I:I"   '\\ Column 9
   Const sMsg As String = _
                        "Your Alert message"    '<<==== CHANGE

   Set Rng = Intersect(Me.Range(sCol), Target)

   If Not Rng Is Nothing Then
       With Rng
           If Rng.Count > Application.CountA(.Cells) Then
               With Application
                   .EnableEvents = False
                   .Undo
                   .EnableEvents = True
                   MsgBox Prompt:=sMsg, Buttons:=vbCritical
               End With
           End If
       End With
   End If
End Sub
'<<==========
---
Regards.
Norman

Give the following worksheet Change event code try (the user will be asked
if he/she really wants to change the value and, if the answer is no, the
original value for the cell will be restored)...

Private Sub Worksheet_Change(ByVal Target As Range)
 Dim Answer As Long
 If Target.Column = 1 Then
   On Error GoTo Done
   Application.EnableEvents = False
   Answer = MsgBox("Changing this value will delete other values " & _
                   "in this row." & vbCrLf & vbCrLf & "Did you " & _
                   "want to still change the cell's value?", vbYesNo)
   If Answer = vbNo Then Application.Undo
 Else
   '
   '  Your non-Column "A" change event code, if any, goes here
   '
 End If
Done:
 Application.EnableEvents = True
End Sub

Rick