How about something like the following then? Note that it is Workbook event
code, not Worksheet event code; to install the code correctly, go into the
VB editor and double click the ThisWorkbook entry in the Project Window and
then copy/paste the code following my signature into the code window that
appears. To make use of the code, just double click a cell that contains a
value you want to find.

Rick

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, _
                     ByVal Target As Range, Cancel As Boolean)
 Dim WS As Worksheet
 Dim CL As Range
 Dim CellList As String
 Dim FirstAddress As String
 Cancel = True
 If Target.Value = "" Then Exit Sub
 For Each WS In Worksheets
   Set CL = WS.UsedRange.Find(Target.Value, LookIn:=xlValues)
   If Not CL Is Nothing Then
       FirstAddress = CL.Address
       Do
           If Len(CellList) = 0 Then
               CellList = WS.Name & " - " & CL.Address
           Else
               CellList = CellList & vbLf & WS.Name & " - " & CL.Address
           End If
           Set CL = WS.UsedRange.FindNext(CL)
       Loop While Not CL Is Nothing And CL.Address <> FirstAddress
   End If
 Next
 MsgBox CellList
End Sub