demo's from the immediate window:

dt = Filedatetime("C:\data\KZ081-Default Survey1.xls")
? cdate(clng(dt))
3/18/02
? dt-clng(dt)
6:08:40 AM

One way:

Option Explicit
Sub testme()

   Dim iRow As Long
   Dim FirstRow As Long
   Dim LastRow As Long
   Dim wks As Worksheet
   Dim testStr As String
   Dim myFileName As String
   Dim myDate As Date
   
   Set wks = Worksheets("sheet1")
   
   With wks
       FirstRow = 2 'headers in row 1???
       LastRow = .Cells(.Rows.Count, "A").End(xlUp).Row
       
       For iRow = FirstRow To LastRow
           myFileName = .Cells(iRow, "A").Value
           testStr = ""
           On Error Resume Next
           testStr = Dir(myFileName)
           On Error GoTo 0
           
           If testStr = "" Then
               .Cells(iRow, "B").Value = "Not Found"
               .Cells(iRow, "C").ClearContents
           Else
               myDate = FileDateTime(myFileName)
               With .Cells(iRow, "B")
                   .NumberFormat = "mm/dd/yyyy"
                   .Value = Int(myDate)
               End With
               
               With .Cells(iRow, "C")
                   .NumberFormat = "hh:mm:ss"
                   .Value = myDate - Int(myDate)
               End With
               
           End If
       Next iRow
   End With            
           
End Sub

Although, I think I'd keep the time and date in one cell.  And just format it
pretty.