Aaron

I assumed the Data Validation cell is B2

I assumed that the list of clients is in a separate sheet named "Utility",
in Column A starting in A1.

I assumed the client list is named  "ListOfClients".

Change the above to suit what you have but note that "Utility" and
"ListOfClients" is written in the code and will have to be changed in the
code if you change them in your file.

The code I wrote for you consists of one sheet macro (belongs in the sheet
module for the sheet that holds the Data Validation cell) and 3 macros that
go in a standard module.

The sheet macro in the sheet module fires whenever the content of ANY cell
in the sheet changes.  The code I wrote in that macro restricts the macro
from doing anything unless the content of B2 changes.  The Data Validation
must be setup to allow the user to type in anything he wants

If the content of cell B2 changes, the code will assign that entry to the
variable ClientName and will call the SetUpClient macro,

If ClientName is in the existing client list, the code will select that
client's sheet and do nothing more.

If the ClientName is NOT in the client list, the code will do the following:

Put that name in the client list.

Sort the client list.

Assign that new list to the B2 Data Validation cell.

Create a new blank sheet with the new client name as the sheet name.

Sort the sheets alphabetically.

Select the new sheet.

Let me know how this works for you and any changes you might want.  Otto

Private Sub Worksheet_Change(ByVal Target As Range)
   If Target.Count > 1 Then Exit Sub
   If Target.Address(0, 0) <> "B2" Then Exit Sub
   If IsEmpty(Target.Value) Then Exit Sub
   ClientName = Target.Value
   Call SetUpClient
End Sub

Option Explicit
Option Compare Text
Dim OnList As Boolean
Public ClientName As String

Sub SetUpClient()
   Application.EnableEvents = False
   Range("B2").ClearContents
   Application.EnableEvents = True
   If Not Range("ListOfClients").Find(What:=ClientName, LookAt:=xlWhole) Is
Nothing Then
       Sheets(ClientName).Select
   Else
       Application.ScreenUpdating = False
       Call PutNameInList
       Sheets(ClientName).Select
       Application.ScreenUpdating = True
   End If
End Sub

Sub PutNameInList()
   With Sheets("Utility")
       .Range("A" & Rows.Count).End(xlUp).Offset(1).Value = ClientName
       .Range("A1", .Range("A" & Rows.Count).End(xlUp)).Name =
"ListOfClients"
       .Range("ListOfClients").Sort Key1:=.Range("A1"),
Order1:=xlAscending, Header:=xlNo, _
           OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom
   End With
   Worksheets.Add.Name = ClientName
   Call SortSheetsAlpha
End Sub

Sub SortSheetsAlpha()
   Dim Counter As Long
   Dim Counter1 As Long
   For Counter = 1 To Sheets.Count - 1
       For Counter1 = Counter + 1 To Sheets.Count
           If Sheets(Counter1).Name < Sheets(Counter).Name Then
               Sheets(Counter1).Move Before:=Sheets(Counter)
               Sheets(Counter + 1).Move Before:=Sheets(Counter1)
           End If
       Next Counter1
   Next Counter
End Sub