Hi shikamikamoomoo

Here is one to test for you
Will finish it tomorrow and add it to the webpage

Copy the function also in the module

Sub Test_More_Areas()
   Dim basebook As Workbook
   Dim mybook As Workbook
   Dim rnum As Long
   Dim FNames As String
   Dim MyPath As String
   Dim SaveDriveDir As String
   Dim Cnum As Integer
   Dim cell As Range

   SaveDriveDir = CurDir
   MyPath = "C:\Data"
   ChDrive MyPath
   ChDir MyPath

   FNames = Dir("*.xls")
   If Len(FNames) = 0 Then
       MsgBox "No files in the Directory"
       ChDrive SaveDriveDir
       ChDir SaveDriveDir
       Exit Sub
   End If

   Application.ScreenUpdating = False
   Set basebook = ThisWorkbook

   Do While FNames <> ""

       If IsError(Application.Match(FNames, _
                                    basebook.Worksheets(1).Columns("A"), 0)) Then
           rnum = LastRow(basebook.Worksheets(1)) + 1
           Set mybook = Workbooks.Open(FNames)

           ' This will add the workbook name in column A if you want
           basebook.Worksheets(1).Cells(rnum, "A").Value = mybook.Name

           ' Copy the cell values from each cell in one row starting in column B
           Cnum = 2
           For Each cell In mybook.Worksheets(1).Range("A2,A3,C2,C3,E2,E3")
               basebook.Worksheets(1).Cells(rnum, Cnum).Value = cell.Value
               Cnum = Cnum + 1
           Next cell
           mybook.Close False
       End If
       FNames = Dir()
   Loop

   ChDrive SaveDriveDir
   ChDir SaveDriveDir
   Application.ScreenUpdating = True
End Sub

Function LastRow(sh As Worksheet)
   On Error Resume Next
   LastRow = sh.Cells.Find(What:="*", _
                           After:=sh.Range("A1"), _
                           Lookat:=xlPart, _
                           LookIn:=xlFormulas, _
                           SearchOrder:=xlByRows, _
                           SearchDirection:=xlPrevious, _
                           MatchCase:=False).Row
   On Error GoTo 0
End Function

I'm not sure what I am doing wrong, but I cannot get this to copy
anything over.  I've tried copying the entire code including the
Function into Module 1.  But when I run it nothing happens.  Do I need
this code plus the original? I changed the path to the right location
and I do not get any errors.