AFAIK it can't be done.

knut

Can't be done.

BUT ... try this to add quotes to the title:

=A1&" "&""""&B1&""""

Hello Everyone,
I guess it is an easy one, but I cannot solve it my own.
I have two cells for a reference list.
Cell A1 contains a name of an author, Cell B1 contains an article
title.

I want to combine both sells in C1 like A1&B1. The problem is that in
Cell C1 the authors name (from A1) should appear normal, while the
titel (from B1) should be in italics or bold (both in the same cell)

anybody idea how to do that.

thanks Kai

You can't do it with a formula, but you could do it with a macro.

Option Explicit
Sub testme()

   Dim myRng As Range
   Dim myCell As Range
   Dim wks As Worksheet
   
   Set wks = Worksheets("Sheet1")
   With wks
       Set myRng = .Range("a2", .Cells(.Rows.Count, "A").End(xlUp))
   End With
   
   For Each myCell In myRng.Cells
       With myCell
           .Offset(0, 2).Value = .Value & " " & .Offset(0, 1).Value
           With .Offset(0, 2).Characters(Len(.Value) + 2, _
                       Len(.Offset(0, 2).Value))
               .Font.Bold = True
               .Font.Italic = True
           End With
       End With
   Next myCell
End Sub

This assumes your data is in sheet1, A2:Axxx, B2:Bxxx and the results go in
C2:Cxxx.

But if you do this (to make things look pretty), don't destroy the original
columns.

You'll find that having the data separated into fields will make
sorting/filter/summarizing much easier.

If you want, just hide those original columns.

If you're new to macros, you may want to read David McRitchie's intro at:
http://www.mvps.org/dmcritchie/excel/getstarted.htm