Averaging compound numbers, e.g. Blood Pressur

Thread view:

Enable EMail Alerts

Start New Thread

Thread rating:

Old Red One - 25 Jul 2006 01:00 GMT

How does one average blood pressure readings? Please give an actual
example, such as 152/65.

Reply to this Message

Dave Peterson - 25 Jul 2006 01:17 GMT

Put each of the blood pressure readings in their own column:

So A2:A999 would hold the top (systolic) reading and
B2:B999 would hold the bottom (diastolic) reading.

Then you could use:

=average(a2:a999) to get the average sytolic
and
=average(b2:b999) to get the average diastolic

> How does one average blood pressure readings? Please give an actual
> example, such as 152/65.

Signature

Dave Peterson

Reply to this Message

Gord Dibben - 25 Jul 2006 01:36 GMT

To get averages of sistolic(high number) and diastolic(low number) pressures you
would have to have them in separate columns.

You would then take an average of each column.

Sistolic in Column A =AVERAGE(A:A)

Diastolic in Column B =AVERAGE(B:B)

Gord Dibben MS Excel MVP

>How does one average blood pressure readings? Please give an actual
>example, such as 152/65.

Reply to this Message

Biff - 25 Jul 2006 01:37 GMT

Hi!

Do you mean you want the average of:

152/65
147/72
147/70

If so, split the values into separate cells then it's just a simple
=AVERAGE(.......) formula.

Use Text to Columns to split the values.

Select the range of cells in question, assume A1:A3
Make sure B1:B3 are empty otherwise any data in those cells will be
overwritten.
Goto the menu Data>Text to Columns
Select Delimited
Next
Select Other
In the little box to the right enter a forward slash: /
Click Finish.

Then you can just use the average formula.

Biff

> How does one average blood pressure readings? Please give an actual
> example, such as 152/65.

Reply to this Message

Biff - 25 Jul 2006 02:07 GMT

Just for the heck of it...........

A1 = 152/65
A2 = 147/72
A3 = 147/70

=ROUND(SUMPRODUCT(--(LEFT(A1:A3,FIND("/",A1:A3)-1)))/ROWS(A1:A3),0)&"/"&ROUND(SUMPRODUCT(--(MID(A1:A3,FIND("/",A1:A3)+1,5)))/ROWS(A1:A3),0)

Returns: 149/69

I don't know anything about blood pressures but you can shorten the formula
if the first value is always 3 digits and the second value is always 2
digits:

=ROUND(SUMPRODUCT(--(LEFT(A1:A3,3)))/ROWS(A1:A3),0)&"/"&ROUND(SUMPRODUCT(--(RIGHT(A1:A3,2)))/ROWS(A1:A3),0)

Biff

> Hi!
>
[quoted text clipped - 25 lines]
>> How does one average blood pressure readings? Please give an actual
>> example, such as 152/65.

Reply to this Message

Old Red One - 25 Jul 2006 05:16 GMT

> Just for the heck of it...........
>
[quoted text clipped - 43 lines]
>>> How does one average blood pressure readings? Please give an actual
>>> example, such as 152/65.

Many, Many thanks. I got 149/70 but I input A1 as 152/68.

152/68
147/72
147/70
149/70

Did you work up this formula on your own? Again thanks, Buck Jordan.

Reply to this Message

Biff - 25 Jul 2006 06:18 GMT

>> Just for the heck of it...........
>>
[quoted text clipped - 52 lines]
>
> Did you work up this formula on your own? Again thanks, Buck Jordan.

This is a hobby for me!

Thanks for the feedback.

Biff

Reply to this Message

Harlan Grove - 25 Jul 2006 05:27 GMT

Biff wrote...

>Just for the heck of it...........
>
[quoted text clipped - 4 lines]
>=ROUND(SUMPRODUCT(--(LEFT(A1:A3,FIND("/",A1:A3)-1)))/ROWS(A1:A3),0)&"/"
>&ROUND(SUMPRODUCT(--(MID(A1:A3,FIND("/",A1:A3)+1,5)))/ROWS(A1:A3),0)

There's a shorter way to deal with this using array entry.

=ROUND(AVERAGE(INT(SUBSTITUTE(A1:A3,"/","."))),0)&"/"
&ROUND(AVERAGE(--MID(A1:A4,FIND("/",A1:A3)+1,4)),0)

>Returns: 149/69
>
>I don't know anything about blood pressures but you can shorten the formula
>if the first value is always 3 digits and the second value is always 2
>digits:

...

Second value could be over 100, and that's very bad.

Since 110/60,110/60,110/60,200/132 is worse than
125/78,125/78,125/78,125/78, I doubt means are as meaningful as medians
or percentiles if the

Reply to this Message

Harlan Grove - 25 Jul 2006 05:29 GMT

Biff wrote...

There's a shorter way to deal with this using array entry.

=ROUND(AVERAGE(INT(SUBSTITUTE(A1:A3,"/","."))),0)&"/"
&ROUND(AVERAGE(--MID(A1:A4,FIND("/",A1:A3)+1,4)),0)

>Returns: 149/69
>
>I don't know anything about blood pressures but you can shorten the formula
>if the first value is always 3 digits and the second value is always 2
>digits:

...

Second value could be over 100, and that's very bad.

Since 110/60,110/60,110/60,200/132 is worse than
125/78,125/78,125/78,125/78, I doubt means are as meaningful as
percentiles or maximums if the goal is early warning for high blood
preasure.

Reply to this Message

Biff - 25 Jul 2006 06:14 GMT

>There's a shorter way to deal with this using array entry.

>=ROUND(AVERAGE(INT(SUBSTITUTE(A1:A3,"/","."))),0)&"/"
>&ROUND(AVERAGE(--MID(A1:A4,FIND("/",A1:A3)+1,4)),0)

I thought about using an array AVERAGE, although I didn't think about using
INT(SUBSTITUTE(A1:A3,"/",".")).

Very clever!

Biff

> Biff wrote...
>>Just for the heck of it...........
[quoted text clipped - 25 lines]
> percentiles or maximums if the goal is early warning for high blood
> preasure.

Reply to this Message

bplumhoff@gmail.com - 27 Jul 2006 14:15 GMT

Hello,

Another one:
=ROUND(AVERAGE(--REPLACE(A1:A3,FIND("/",A1:A3),9,"")),0)&"/"&ROUND(AVERAGE(--REPLACE(A1:A3,1,FIND("/",A1:A3),"")),0)

But this is a little bit slower than Biff's (quickest) and Harlan's
solution.

Regards,
Bernd

Reply to this Message

GSalisbury - 25 Jul 2006 14:15 GMT

> How does one average blood pressure readings? Please give an actual
> example, such as 152/65.

I happen to have workbook for this exact task.
It's self-contained Excel97 - no macros.
You can enter up to four sets readings (high/low/pulse) across a line and
each line is a day.
The date and times rounded to nearest five minutes are automatically posted.
The min, maxes and averages are all automatically calculated.
I'd be happy to send it to you as an example.
Geo. Salisbury

Reply to this Message

Old Red One - 25 Jul 2006 17:00 GMT

>> How does one average blood pressure readings? Please give an actual
>> example, such as 152/65.
[quoted text clipped - 8 lines]
> I'd be happy to send it to you as an example.
> Geo. Salisbury

It would be most interesting to see;lease do send it. Is it your own work?
Please also give your correct e-mail address. Thanks, Buck Jordan.
oldred1@charter.net.

Reply to this Message

GSalisbury - 27 Jul 2006 01:58 GMT

> >> How does one average blood pressure readings? Please give an actual
> >> example, such as 152/65.
[quoted text clipped - 12 lines]
> Please also give your correct e-mail address. Thanks, Buck Jordan.
> oldred1@charter.net.

Yes it is my own construction but I did get some good pointers here in this
NG.

I was working on the date aspect, for example, and someone else posted a
rounding dates query in Nov, 2005 and Bob Phillips posted a perfect reply
which I was able to adapt for my needs. Also, at that same time, I posted a
request for help resolving a "circular reference..." issue and Peo Sjoblom
provided a pointer to a Tools>Options>Calculation Iteration check box which
was exactly the fix for my situation.

News Groups rule!

My e-mail is pretty much as my header says: salsburyg at comcast dot net.
Substitute the "at" for an at-sign "@" and the "dot" for a dot "." and
remove all spaces of course.

I'd appreciate a critique.
Thx
Geo. S.

Reply to this Message