Hi Bernie

This example loop through row 1 - 100 on the activesheet and if the value in A is the same as in
Sheets("Yoursheet").Range("A1").Value in delete the row

Maybe you can use a Autofilter if you have many rows (faster)
See this page for more info
http://www.rondebruin.nl/delete.htm

Sub Example2()
   Dim Lrow As Long
   Dim CalcMode As Long
   Dim ViewMode As Long
   Dim StartRow As Long
   Dim EndRow As Long

   With Application
       CalcMode = .Calculation
       .Calculation = xlCalculationManual
       .ScreenUpdating = False
   End With

   ViewMode = ActiveWindow.View
   ActiveWindow.View = xlNormalView

   With ActiveSheet
       .DisplayPageBreaks = False
       StartRow = 1
       EndRow = 100

       For Lrow = EndRow To StartRow Step -1

           If IsError(.Cells(Lrow, "A").Value) Then
               'Do nothing, This avoid a error if there is a error in the cell

           ElseIf .Cells(Lrow, "A").Value = Sheets("Yoursheet").Range("A1").Value Then .Rows(Lrow).Delete
               'This will delete each row with the Value "ron" in Column A, case sensitive.

           End If
       Next
   End With

   ActiveWindow.View = ViewMode
   With Application
       .ScreenUpdating = True
       .Calculation = CalcMode
   End With

End Sub