Mika,

With your interval size (1, 2,3,4, or 5) entered into cell B1:

=IF(MIN(OFFSET(OFFSET(A10,-$B$1,0,1,1),0,0,2*$B$1+1,1))=A10,"MIN","NOT MIN")

for the value in cell A10....

HTH,
Bernie
MS Excel MVP

One way:

   Public Function RelativeMin( _
           ByRef rP As Range, _
           byVal x As Long, _
           Optional ByVal bCol As Boolean = True _
           ) As Variant
       Dim rRange As Range
       Dim i As Long
       Dim bResult As Boolean

       Application.Volatile
       On Error GoTo ErrorHandler
       bResult = True      'assume minimum
       With rP(1)
           If bCol Then
               Set rRange = .Offset(-x, 0).Resize(2 * x + 1, 1)
           Else
               Set rRange = .Offset(0, -x).Resize(1, 2 * x + 1)
           End If
       End With
       For i = 1 To x
           If rRange(i) <= rRange(i + 1) Or _
                   rRange(x + i) >= rRange(x + i + 1) Then
               bResult = False
               Exit For
           End If
       Next i
       RelativeMin = bResult
   ResumeHere:
       Exit Function
   ErrorHandler:
       RelativeMin = CVErr(xlErrRef)
       Resume ResumeHere
   End Function

Call as (for data in column):
   
   =RelativeMin(P3, x)

or

   =IF(RelativeMin(P3,x,TRUE), "P3 is Min", "P3 is not Min")

For data in row:

   =RelativeMIn(P3, x, FALSE)

Obviously, this could do with more error handling, but it should do as a
template.