One way:

Put this in your worksheet code module (right-click the worksheet tab
and choose View Code):

   Private Sub Worksheet_Change(ByVal Target As Excel.Range)
       Const cdINCREMENT As Double = 199
       With Range("A1")
           If Not Intersect(Target, .Cells) Is Nothing Then
               If IsNumeric(.Value) Then
                   On Error Resume Next
                   Application.EnableEvents = False
                   .Value = CStr(.Value) & " - " & _
                           CStr(.Value + cdINCREMENT)
                   Application.EnableEvents = True
               End If
           End If
       End With
   End Sub

I think you'd be much better served by using different cells for this kind of
thing.

But if you have to, you could use a worksheet event and have it do the work.

Rightclick on the worksheet tab that should have this behavior and select view
code.  Paste this into the code window:

Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)

   With Target
       'only one cell at a time
       If .Cells.Count > 1 Then Exit Sub
       
       'only in column A
       If Intersect(.Cells, Me.Range("a:a")) Is Nothing Then
           Exit Sub
       End If
       
       On Error GoTo ErrHandler:
       
       'no errors
       If IsError(.Value) Then Exit Sub
       
       'no empty cells
       If IsEmpty(.Value) Then Exit Sub
       
       'no formulas
       If .HasFormula Then Exit Sub
       
       'only numbers
       If IsNumeric(.Value) = False Then Exit Sub
       
       'do the work
       Application.EnableEvents = False
       .Value = .Value & " - " & .Value + 199
   
   End With
       
       
ErrHandler:
       Application.EnableEvents = True

End Sub

You'll have to change the range (I used column A).  And you may want to use a
line like:

.Value = format(.Value, "000000") & " - " & format(.Value + 199, "000000")

If you have any leading 0's in those numbers that have to be kept.