I think you'll have to open the workbooks--but you can do that work in a macro.

Maybe something like this untested, but compiled code:

Option Explicit
Sub testme01()
 
   Dim myNames() As String
   Dim fCtr As Long
   Dim myFile As String
   Dim myPath As String
   Dim TempWkbk As Workbook
   
   'change the folder here
   myPath = "C:\my documents\excel\test\Schedules"
   If myPath = "" Then Exit Sub
   If Right(myPath, 1) <> "\" Then
       myPath = myPath & "\"
   End If
   
   myFile = ""
   On Error Resume Next
   myFile = Dir(myPath & "*.xls")
   On Error GoTo 0
   If myFile = "" Then
       MsgBox "no files found"
       Exit Sub
   End If
   
   'get the list of files
   fCtr = 0
   Do While myFile <> ""
       fCtr = fCtr + 1
       ReDim Preserve myNames(1 To fCtr)
       myNames(fCtr) = myFile
       myFile = Dir()
   Loop

   If fCtr > 0 Then
       For fCtr = LBound(myNames) To UBound(myNames)
           Set TempWkbk = Workbooks.Open(Filename:=myPath & myNames(fCtr))
           Application.Run "'" & TempWkbk.Name & "'!ClearBalances"
           TempWkbk.Save
           TempWkbk.Close savechanges:=False
       Next fCtr
   End If
 
End Sub