So you have some text that can be used multiple times that shouldn't be included
in the duplicate search?

Option Explicit
Sub testme()

   Dim myRng As Range
   Dim myFormula As String
   Dim NumberOfUniqueEntries As Long
   Dim myOkDupe As String
   Dim NumberOfOkDupes As Long
   
   myOkDupe = "DNA" 'like "does not apply
       
   With Worksheets("sheet1")
       Set myRng = .Range("a7", .Cells(.Rows.Count, "A").End(xlUp))
   End With
   
   myFormula = "sumproduct((" & myRng.Address(external:=True) & "<>"""")" _
                   & "/countif(" & myRng.Address(external:=True) & "," _
                   & myRng.Address(external:=True) & "&""""))"
           
   NumberOfUniqueEntries = Application.Evaluate(myFormula)
   
   NumberOfOkDupes = Application.CountIf(myRng, myOkDupe)
   If NumberOfOkDupes > 0 Then
       NumberOfUniqueEntries = NumberOfUniqueEntries - 1
   End If
   
   If NumberOfUniqueEntries + NumberOfOkDupes = Application.CountA(myRng) Then
       MsgBox "All Unique"
   Else
       MsgBox "Duplicates"
   End If

End Sub

Say you have:
xxx
dna
yyy
dna
zzz
dna

Then the number of uniques would be 4.  
The number of dna's is 3.  But since dna is counted in both the number of
uniques and the number of dna's, we subtract one.  (The code subtracted 1 from
the numberofuniqueentries.)