Dave,

Code works. Many thanks to you and the other posters to my problem. This
will save me hours of work.

Thanks again, post can now be closed.

Saruman

How about this one--it might be quicker if there are lots of cells to be fixed:

Option Explicit
Sub testme()

   Dim myCell As Range
   Dim myRng As Range
   Dim cCtr As Long
 
   Set myRng = Nothing
   On Error Resume Next
   Set myRng = Intersect(Selection, _
                  Selection.Cells.SpecialCells(xlCellTypeConstants))
   On Error GoTo 0
   
   If myRng Is Nothing Then
       MsgBox "Please select a nice range"
       Exit Sub
   End If
   
   If myRng.Cells.Count < 2 Then
       Set myRng = Union(myRng, _
         ActiveSheet.Cells.SpecialCells(xlCellTypeLastCell).Offset(1, 1))
   End If
   
   myRng.Replace what:=vbLf, _
                replacement:=Space(1), _
                lookat:=xlPart, _
                MatchCase:=False
               
   For Each myCell In myRng.Cells
       myCell.Value = Application.Trim(myCell.Value)
   Next myCell
   
   For cCtr = 0 To 9
           myRng.Replace what:=cCtr & " ", _
                replacement:=cCtr & vbLf, _
                lookat:=xlPart, _
                MatchCase:=False
   Next cCtr
       
End Sub

It looks like every string that ends with a number (followed by a space) is
converted to that number followed by alt-enter.

I couldn't think of a way to do an Edit|Replace to get rid of any leading or
trailing spaces--so I still had to loop through each cell using
application.trim().