I think I understand, you want the text from inside a text box on a
webpage. For example, you want the contents of the search box from the
google homepage.

If you go to google.com and click on View>Source (in Internet
Explorer) there is a single text box:

<input maxlength=2048 name=q size=55 title="Google Search" value="">

Technically it is called an input box. You should make a note of the
name "q" which you would use to identify the contents.

If you set a reference to the Internet Explorer object (shdocvw.dll)
then you can use this code:

Sub GoToGoogleWithEarlyBinding()
Dim appIE As InternetExplorer
Dim sURL As String
Dim SearchBox As Variant

Set appIE = New InternetExplorer
sURL = "http://www.google.com"

With appIE
   .Navigate sURL
   .Visible = True
End With

' loop code until page is fully loaded
Do While appIE.Busy
Loop

Set SearchBox = appIE.Document.getElementsByName("q")

If Not SearchBox Is Nothing Then
SearchBox(0).Value = "2eXtreme"
End If

End Sub

Or if you didn't want to set a reference to the IE object library,
this code would work:

Sub GoToGoogleWithLateBinding()
Dim appIE As Object
Set appIE = CreateObject("Internetexplorer.application")
Dim sURL As String
Dim SearchBox As Variant

sURL = "http://www.google.com"

With appIE
   .Navigate sURL
   .Visible = True
End With

' loop code until page is fully loaded
Do While appIE.Busy
Loop

Set SearchBox = appIE.Document.getElementsByName("q")

If Not SearchBox Is Nothing Then
SearchBox(0).Value = "2eXtreme"
End If

End Sub

Step through the code and you can see how it creates a new IE window,
finds the textbox and inserts a value. If you needed the searchbox
result for a particular page, click View>Source and find the name of
the input box, then set a reference to it using "Set SearchBox =
appIE.Document.getElementsByName("input box name")" and extract the
value by assigning it to a variable, such as

Dim X As String
X = SearchBox(0).Value

Then you can insert it into a cell like this: Range("A1") = X

HTH,
JP

On Feb 26, 7:33 pm, fgrib...@gmail.com wrote: