There's nothing built into excel that lets you do this kind of thing.

But you can use a User Defined Function (UDF):

Option Explicit
Function SumByNumberFormat(rng As Range, NumFmt As String) As Double

   Dim myCell As Range
   Dim mySum As Double
   
   Application.Volatile
   mySum = 0
   For Each myCell In rng.Cells
       If Application.IsNumber(myCell.Value) Then
           If LCase(myCell.NumberFormat) = LCase(NumFmt) Then
               mySum = mySum + myCell.Value
           End If
       End If
   Next myCell
   
   SumByNumberFormat = mySum
           
End Function

Be aware that if you change the numberformat of any of the cells, then this
formula cell won't change until your workbook calculates.

If you're new to macros, you may want to read David McRitchie's intro at:
http://www.mvps.org/dmcritchie/excel/getstarted.htm

Short course:

Open your workbook.
Hit alt-f11 to get to the VBE (where macros/UDF's live)
hit ctrl-R to view the project explorer
Find your workbook.
should look like:   VBAProject (yourfilename.xls)  

right click on the project name
Insert, then Module
You should see the code window pop up on the right hand side

Paste the code in there.

Now go back to excel.
Into a test cell and type:
=sumbynumberformat(A1:A5,"#,##0.00_);(#,##0.00)")

You'll change the numberformat string to whatever you need.