I don't know of any addin that does what you want, but you could record a macro
when you sorted one worksheet manually.  Then run that macro against all (or
some of) the worksheets in your workbook.

I recorded a macro and tweaked it to sort the same columns (A:L) and used the
data in column A to determine the last row to sort.  I also said that headers
were in Row 1 only.

The first sub sorts all the worksheets in that workbook.

Option Explicit
Sub testme()
   Dim wks As Worksheet
   For Each wks In ActiveWorkbook.Worksheets
       With wks
           .Range("a1:L" & .Cells(.Rows.Count, "A").End(xlUp).Row).Sort _
               key1:=.Range("a1"), order1:=xlDescending, _
               header:=xlYes, MatchCase:=False
       End With
   Next wks
End Sub

If you don't want to sort all the sheets, you can specify which ones you want
with something like this:

Sub testme2()
   Dim wks As Worksheet
   Dim myWksNames As Variant
   
   myWksNames = Array("sheet1", "sheet2")
   
   For Each wks In ActiveWorkbook.Worksheets(myWksNames)
       With wks
           .Range("a1:L" & .Cells(.Rows.Count, "A").End(xlUp).Row).Sort _
               key1:=.Range("a1"), order1:=xlDescending, _
               header:=xlYes, MatchCase:=False
       End With
   Next wks
End Sub

If you're new to macros, you may want to read David McRitchie's intro at:
http://www.mvps.org/dmcritchie/excel/getstarted.htm

====
And for a different approach, you may want to take a look at the worksheet
function =Rank().  Maybe you don't even need to sort all your data.