This may help you:

Option Explicit
Sub testme()

   Dim myCB As CommandBar
   Dim myCtrl As CommandBarControl
   Dim iCtr As Long
   Dim DestCell As Range
   
   Set DestCell = Workbooks.Add(1).Worksheets(1).Range("a1")
   DestCell.Resize(1, 4).Value _
       = Array("CommandBar Name", "Menu Name", "Control Caption", "OnAction")
   Set DestCell = DestCell.Offset(1, 0)
   
   For Each myCB In CommandBars
       For iCtr = 1 To myCB.Controls.Count
           On Error Resume Next
           With myCB.Controls(iCtr)
               If .BuiltIn = False Then
                   If .Type = msoControlPopup Then
                       For Each myCtrl In .Controls
                           DestCell.Value = myCB.Name
                           DestCell.Offset(0, 1).Value = .Caption
                           DestCell.Offset(0, 2).Value = myCtrl.Caption
                           DestCell.Offset(0, 3).Value = myCtrl.OnAction
                           Set DestCell = DestCell.Offset(1, 0)
                       Next myCtrl
                   Else
                       DestCell.Value = myCB.Name
                       DestCell.Offset(0, 2).Value = .Caption
                       DestCell.Offset(0, 3).Value = .OnAction
                       Set DestCell = DestCell.Offset(1, 0)
                   End If
                   
               End If
           End With
           On Error GoTo 0
       Next iCtr
    Next myCB
   
    With DestCell.Parent
       .Select
       .Range("A1").Select
       .Range("a2").Select
       ActiveWindow.FreezePanes = True
       With .UsedRange.Columns
           .AutoFilter
           .AutoFit
       End With
   End With
End Sub