IF(OR((A1<-1),(A1>1)),REPT("*",3),A1)

replace A1 for your fuction if it is need and format the cell as %

hth

I don't think you can use this many parts in a custom format.

You could use another cell containing a formula -- like Marcelo suggested.

Or you could use a worksheet event that changes the formatting.

If you want to try...

Right click on the worksheet tab that should have this behavior.  Select view
code and paste this into the code window that just opened:

Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
   'one cell at a time
   If Target.Cells.Count > 1 Then
       Exit Sub
   End If

   'only look at A2:A10
   If Intersect(Target, Me.Range("A2:A10")) Is Nothing Then
       Exit Sub
   End If

   If IsNumeric(Target.Value) = False Then
       Target.NumberFormat = "General"
   Else
       '< -1      Cell displays ***
       '0 to -1   Cell displays (#0%)
       '0 to 1    Cell displays #0%
       '>1        Cell displays ***
       Select Case Target.Value
           Case Is < -1
               Target.NumberFormat = ";""***"";;"
           Case Is < 0
               Target.NumberFormat = ";(#0%);;"
           Case Is < 1
               Target.NumberFormat = "#0%"
           Case Else
               Target.NumberFormat = """***"";;;"
       End Select
   End If

End Sub
I only looked at the range A2:A10.  Change that to what you need.