Presenter's View might serve your needs.  Have you tried it?  Go to Slide Show >
Set Up Show and set it to display the Presenter's View.

Someone else asked about this a while ago. I came up with a little macro
that puts a bar at the bottom of each slide with the title of the next
slide. If you put this macro into your presentation, you can put a button
on the first slide. When you click the button, it puts a "footer" on each
slide with the title of the next slide in it. Here's the macro:

Sub Footerize()
   Dim i As Long
   Dim shp As Shape
   Dim hasFooter As Boolean
   Dim newFooterBox As Shape
   
   For i = 1 To ActivePresentation.Slides.Count - 1
       hasFooter = False
       For Each shp In ActivePresentation.Slides(i).Shapes
           If shp.Name = "MyVeryOwnFooter" Then
               hasFooter = True
           End If
       Next
       If hasFooter = True Then
           ActivePresentation.Slides(i).Shapes("MyVeryOwnFooter") _
               .TextFrame.TextRange.Text = _
               ActivePresentation.Slides(i + 1).Shapes(1) _
               .TextFrame.TextRange.Text
       Else
           Set newFooterBox = _
               ActivePresentation.Slides(i).Shapes.AddShape _
               (msoTextOrientationHorizontal, 0#, 504#, 720#, 28.875)
           newFooterBox.Name = "MyVeryOwnFooter"
           newFooterBox.TextFrame.TextRange.Text = _
               ActivePresentation.Slides(i + 1).Shapes(1) _
               .TextFrame.TextRange.Text
           newFooterBox.TextFrame.TextRange.Font.Size = 10
           newFooterBox.TextFrame.TextRange.ParagraphFormat.Alignment _
               = ppAlignCenter
       End If
   Next i
End Sub

Of course, this only works well if the title placeholder is used for each
slide. Also, the color, size, and location of the "footer" can be easily
changed to make it less obtrusive.

--David