AQs long as you have installed the fax printer driver (I think iti s
installed when you set up Microsoft Fax, which comes with Win XP, for
example), then you can print to the fax printer driver, saving the output as
a file.

e.g. in Word VBA, something like

' Specify the path for the .tif files saved by the Fax Printer
' This path must exist and the name should end with "\"
Const sTifFolder = "c:\tif\"
' Specify the name of the .tif file to output
Const sTifFile = "mergetif.tif"
' Specify the fax printer name that makes it all work
Const sFaxPrinter = "Fax"

Dim oApp As Word.Application
Dim sActivePrinter As String
Dim sTifPath As String

Set oApp = Application

' save and set up the active printer
sActivePrinter = oApp.ActivePrinter

' don't change the printer if it is already
' correctly set up

' you may need to adjust this for your
' fax printer name

If Left(sActivePrinter, 3) <> sFaxPrinter Then
 oApp.ActivePrinter = sFaxPrinter
End If

' Now print to the fax printer, specifying an
' OutputFileName.
' Specifying Background:=False is
' particularly important

' create the full path name for the file.
' (done separately so you can change the way
' you create the name and re-use the name later)

sTifPath = sTifFolder + sTifFile
oApp.PrintOut _
 Background:=False, _
 Append:=False, _
 Range:=wdPrintAllDocument, _
 OutputFileName:=sTifPath, _
 Item:=wdPrintDocumentContent, _
 Copies:=1, _
 PageType:=wdPrintAllPages, _
 PrintToFile:=True

' Restore the previous printer
' if necessary. You may need to tweak this
If Left(sActivePrinter, 3) <> sFaxPrinter Then
 oApp.ActivePrinter = sActivePrinter
End If

' maybe...
'Set oApp = Nothing

Peter Jamieson

Hi Bob,

If you're using Word 2003 and have added the optional install MS Office Document Imaging feature with MS Office Document Image
Writer (printer) and/or with Word 2003 the MS Office Live Meeting Printer. You can print documents to TIF.

Check in Start=>Program=<Microsoft Office=>Microsoft Office tools
to see if Microsoft Office Document Imaging is installed.

=============
Need to save a word doc to a tif file format.  customer has a fax server
computer with acustom fax outbox but it accepts only tiff files for sending.

All we would need to do is to be able to say save as filename in tif format
to the outbox, it would pick up th new file and send it.

How does one make a word doc in tif format?

Thanks,

Bob >>