I think you can also do this, but I haven't tested it much so it may break
down very easily:

Sub testinsert()
' a test routine to insert the IF field that Feng needs at a specified range
Dim f As String
Dim s As String
s = "{ IF ""{ MERGEFIELD LName }"" = """" " & _
"""{ INCLUDEPICTURE ""c:\\blah.gif"" }"" " & _
""""" }"
Debug.Print s
Dim r As Range
Set r = Selection.Range
Call insertfs(s, r)
Set r = Nothing

End Sub

Sub insertfs(ByVal s As String, ByVal r As Range)
' Inserts a string + fields where
' "{" means "opening field brace"
' "}" means "closing field brace"
' "?{" means "ordinary opening brace"
' "?}" means "ordinary closing brace"
' "??" means "? character"
' "?" followed by any other character is discarded

Const EscapeChar = "?"
Dim i As Long
Dim esc As Boolean
Dim buf As String
esc = False
buf = ""
For i = 1 To Len(s)
 c = Mid(s, i, 1)
 Select Case c
 Case EscapeChar:
   If esc Then
     buf = buf + c
     esc = False
   Else
     esc = True
   End If
 Case "{"
   If esc Then
     buf = buf + c
     esc = False
   Else
     r.Text = buf
     buf = ""
     r.Collapse direction:=wdCollapseEnd
     r.Fields.Add Range:=r, Type:=wdFieldEmpty, Text:="",
preserveformatting:=False
     Set r = ActiveDocument.Range(r.Start + 1, r.Start + 1)
     r.Delete unit:=wdCharacter, Count:=2
   End If
 Case "}"
   If esc Then
     buf = buf + c
     esc = False
   Else
     r.InsertAfter Text:=buf
     buf = ""
     r.Collapse direction:=wdCollapseEnd
     Set r = ActiveDocument.Range(r.End + 1, r.End + 1)
   End If
 Case Else
   buf = buf + c
 End Select
Next
r.InsertAfter Text:=buf
End Sub

If you were including strings with arbitrary content including "{", "}" or
"?" characters, you would need to "escape" them using e.g.

Function escapefs(s As String) As String
Const EscapeChar = "?"
escapefs = Replace(Replace(Replace(s, EscapeChar, EscapeChar + EscapeChar),
"{", EscapeChar + "{"), "}", EscapeChar + "}")
End Function

I've avoided using the usual  escape characters
/, \, ^ on the grounds that they are more likely to be used in the strings
you want to code. Well, \ is, I suppose

--
Peter Jamieson
MS Word MVP

Thanks a lot, this really cleared up a lot of my questions.
   
    ----- Cindy M  -WordMVP- wrote: -----
   
    Hi =?Utf-8?B?RmVuZw==?=,
   
    > I'm kind of familiar with inserting nested fields from VB.  I have done this
    with an includepicture field and a merge field.  However in this case, I don't
    even know the syntax of inserting a normal if field or a skipif field using VB.  
    I'm currently trying to automate this on Word 97.
    >  
    Right, I just wanted to know the extent of your background with Word/fields.
   
    > Is there somewhere that has the syntax of how to insert all the word fields and
    what each field does?
    >
    What each field does: look it up in Word's Help files
    Inserting individual fields: the .Add method of the Fields collection. You can
    use the .Type argument with a wdField-constant (you can get a list of these from
    the Object Browser in Word's Help window by searching on wdField) OR you can
    simply include the field's name in the TEXT argument.
   
    Nesting fields is a trickier proposition, however, as Microsoft didn't give us
    any way to do this directly using VBA. Usually, I use Word's Find functionality.
    I insert the outermost field code first, and put some kind of place holder text
    where the inserted field should go. I then use Find to get hold of the
    placeholder and insert the nested field in its place.
   
    Here's a sample:
   
    Sub CreateFieldInField()
        Dim fld As Word.Field
        Dim szQuotes As String
       
        szQuotes = Chr(34)
        Set fld = ActiveDocument.Fields.Add(Range:=Selection.Range, _
          Type:=wdFieldIf, Text:="bkm <> bkm " & szQuotes & _
            "Please change the bkmAUTHORbkm setting in File/Properties" _
            & szQuotes, PreserveFormatting:=False)
        InsertFieldInFieldCode fld.Code, "bkm", "Author"
        InsertFieldInFieldCode fld.Code, "bkm", "UserName"
        InsertFieldInFieldCode fld.Code, "bkm", "Symbol 34"
        InsertFieldInFieldCode fld.Code, "bkm", "Symbol 34"
        fld.Update
    End Sub
   
    Function InsertFieldInFieldCode( _
      ByRef rng As Word.Range, _
      ByRef szBkm As String, _
      ByRef szField As String, _
      Optional ByRef PF As Boolean = False) As Boolean
     
        InsertFieldInCode = False
        With rng.Find
            .Text = szBkm
            .Execute
            If .Found Then
                ActiveDocument.Fields.Add _
                  Range:=rng, Text:=szField, _
                  PreserveFormatting:=PF
                InsertFieldInCode = True
            End If
        End With
    End Function
   
   
    Cindy Meister
    INTER-Solutions, Switzerland
    http://homepage.swissonline.ch/cindymeister (last update Sep 30 2003)
    http://www.mvps.org/word
   
    This reply is posted in the Newsgroup; please post any follow question or reply
    in the newsgroup and not by e-mail :-)