Is this a label format that you created yourself, rather than one of the
ones that you can select in the Label Options dialog.  If so, you may need
to copy and paste the mergefields that you set up in the first label into
each of the other labels on the sheet rather than trying to use the Update
all labels facility.  I suspect that you may have a blank row between each
of your rows of labels and while the Update labels facility somehow knows to
avoid inserting the mergefields into such rows with the labels that you can
select, it may not know how to handle the situation that you have.

The following macro was developed to overcome the problem that hte Update
labels facility has when a Tablet PC is being used, but it should also be
able to be used for your situation as well as a means of copying the label
setup from the first label to the other labels:

Macro created by Doug Robbins to overcome the problem with propagation of
mail merge field fields with a label type mail merge when using a Tablet PC
and some other Computers that have Tablet PC Functionality available:

Sub MailMergePropagateLabel()

Dim atable As Table

Dim i As Long, j As Long

Dim source As Cell, target As Cell

Dim myrange As Range

Set atable = ActiveDocument.Tables(1)

Set source = atable.Cell(1, 1)

Set myrange = source.Range

myrange.Collapse wdCollapseStart

ActiveDocument.Fields.Add Range:=myrange, Text:="NEXT", _

PreserveFormatting:=False

source.Range.Copy

For j = 2 To atable.Columns.Count

   Set target = atable.Cell(1, j)

   If target.Range.Fields.Count > 0 Then

       target.Range.Paste

   End If

Next j

For i = 2 To atable.Rows.Count

   For j = 1 To atable.Columns.Count

        Set target = atable.Cell(i, j)

        If target.Range.Fields.Count > 0 Then

             target.Range.Paste

        End If

   Next j

Next i

atable.Cell(1, 1).Range.Fields(1).Delete

End Sub

It is suggested that you put this code into a template that you save in the
Word Startup folder so that it becomes an add-in and will be available
whenever you need it.  As the macro has the same name as the Word Command
that is supposed to do the job, this macro will run when the Update Labels
button is used when setting up the mail merge label main document.