Here (Word 2003, Win XP, two tray HP OfficeJet L7700 attached via wireless
LAN), if I do the following it works OK:
a. create a new mail merge document, type "Letter".
b. Attach it to a data source
c. insert two page breaks
d. put some text and fields on page one and some text on pages 2 and 3
e. go into File|Print setup and say that the first page should go to Tray 1
and the others to Tray 2
f. merge to printer. I get the output I expect
g. merge to a new document, then print. I get the output I expect.

In other words, here, with a small experimental merge, it works OK. The
reason I asked my questions was because I wanted to be sure that you were
assigning the trays in the same way (i.e. not using section breaks to do
it), that you had actually specified that the merge was a "Letter" merge,
not a "Directory" merge (because the output may look the same, but is not
the same. People sometimes have to do a Directory merge to achieve the
output they want, even though they are actually producing Letters), etc. If
you are actually concerned about the fact that you get an 8000-page /print
job/ instead of 1000 8-page /print jobs/ because you are usuing facilites
outside Word to define the trays for first page /in the job/ and subsequent
pages /in the job/, then you either need to do it Word's way or use a macro
to produce the output as 1000 separate jobs.

One thing you can look at: let's suppose you do the same tray assignment
that I have described above. If you merge to a new document, then click in
letter 1, then look at File|Page Setup|Paper, do you still see that tray
assignment? If you look in the status bar at the bottom left of the Word
window, do you see "Sec 1" (i.e. section 1). If you then click in letter 2,
do you still see the same tray assignment? Do you see "Sec 2" in the status
bar? If you click in any other letter, do you see the same tray assignment,
and the appropriate section number in the Status bar? (Worth checking the
last two letters as well).

If you see "Sec 1" for every page you look at, then either you are using a
Directory merge or something else is wrong.

If you do not see the correct tray assignment for each section then Word is
probably getting it wrong.

Otherwise, the problem is probably in the printer driver or some other part
of the printing subsystem. This is not unknown. I think in that case you can
probably work around the problem using a macro that does one merge for each
record in the data source, e.g.

Sub PrintOneDocPerSourceRec()
Dim intSourceRecord
Dim objMerge As Word.MailMerge
'Dim strOutputDocumentName As String
Dim TerminateMerge As Boolean

' Need to set up this object as the ActiveDocument changes when the
' merge is performed. Besides, it's clearer.

Set objMerge = ActiveDocument.MailMerge
With objMerge

 ' If no data source has been defined, do it here using OpenDataSource.
 ' But if it is already defined in the document, you should not need
 ' to define it here.

 ' .OpenDataSource _
 ' Name:="whatever"

 intSourceRecord = 1
 TerminateMerge = False

 Do Until TerminateMerge
   .DataSource.ActiveRecord = intSourceRecord

   ' if we have gone past the end (and possibly, if there are no records)
   ' then the Activerecord will not be what we have just tried to set it to

   If .DataSource.ActiveRecord <> intSourceRecord Then
     TerminateMerge = True
   ' the record exists
   Else

     .DataSource.FirstRecord = intSourceRecord
     .DataSource.LastRecord = intSourceRecord
     .Destination = wdSendToPrinter
     .Execute

     intSourceRecord = intSourceRecord + 1
   End If
 Loop
End With
End Sub

With 1000 records, you might find that you need to split this process into
several parts.

You may also find the following useful:
http://word.mvps.org/FAQs/MacrosVBA/CreateAMacro.htm
http://word.mvps.org/FAQs/MailMerge/MergeStraightToPrintrWVBA.htm