If all that you are wanting to do is create a document that contains the
data of one particular row in your spreadsheet, I would use a different
approach - a userform containing a combobox that was populated with the data
from the spreadsheet so that you could select an individual item and then
click on a command button on the form so that the datat from that item would
be inserted into the document.

To get started, see the article "How to create a Userform" at:

http://word.mvps.org/FAQs/Userforms/CreateAUserForm.htm

Then to load a combobox on the userform with the data from a range that is
named "Contacts" in a workbook Contacts.xls that is saved in the same folder
as your template, you would use the following initialize routine for the
userform:

   Private Sub UserForm_Initialize()

   ' Requires that a reference be set to the Microsoft DAO 3.6 Object
Library

   ' Open the file containing the Contacts, assumed to be in the same
folder as the template

   Set db = OpenDatabase(ThisDocument.Path & Application.PathSeparator &
"Contacts.xls", False, False, "Excel 8.0")

   ' Retrieve the recordset

   Set rs = db.OpenRecordset("SELECT * FROM `Contacts`")

   ' Determine the number of retrieved records

   With rs

        .MoveLast

        i = .RecordCount

        .MoveFirst

   End With

   ' Set the number of Columns = number of Fields in recordset

   cmbContacts.ColumnCount = rs.Fields.Count

   ' Load the Contacts combobox with the retrieved records

   cmbContacts.Column = rs.GetRows(i - 1)

   ' Cleanup

   rs.Close

   db.Close

   Set rs = Nothing

   Set db = Nothing

The reason that I am not loading the last record in the record set is that
in the Excel spreadsheet, that row should contain a message that if
additional records are to be added, they must be inserted a row that you
insert before what was the last row of the named range, so that the new
record would automatically be included in the named range and thus be loaded
into the combobox.

To get the data from the individual cells of the selected item, you use the
.BoundColumn property of the combobox.  Assuming that you had a list of
contacts in the spreadsheet with data in the following columns:

FirstName

LastName

Street

City

State

Zip

and you use inserted the following { DOCVARIABLE } fields in the template in
the places where you wanted the data to appear

{ DOCVARIABLE varFirstName }

{ DOCVARIABLE varLastName }

{ DOCVARIABLE varStreet }

{ DOCVARIABLE varCity }

{ DOCVARIABLE varState }

{ DOCVARIABLE varZip }

You would use the following in the Command Button Click Event

With ActiveDocument

   cmbContacts.BoundColumn = 1

   .Variables("varFirstName").Value = cmbContacts.Value

   cmbContacts.BoundColumn = 2

   .Variables("varLastName").Value = cmbContacts.Value

   cmbContacts.BoundColumn = 3

   .Variables("varStreet").Value = cmbContacts.Value

   cmbContacts.BoundColumn = 4

   .Variables("varCity").Value = cmbContacts.Value

   cmbContacts.BoundColumn = 5

   .Variables("varState").Value = cmbContacts.Value

   cmbContacts.BoundColumn = 6

   .Variables("varZip").Value = cmbContacts.Value

   .Fields.Update

End With