Hi Shelly,

There is an issue with the propagation of the label set up when using a
Tablet PC (and also it appears when running under Vista with some other
hardware configurations.  Microsoft have been made aware of the issue and
have created a Knowledge Base article at:

http://support.microsoft.com/kb/898630

which does contain a work around.

A better work around however is to use the following macro that I created to
overcome the problem with propagation of mail merge field fields with a
label type mail merge when using a Tablet PC and some other Computers that
have Tablet PC Functionality available:

Sub MailMergePropagateLabel()

Dim atable As Table

Dim i As Long, j As Long

Dim source As Cell, target As Cell

Dim myrange As Range

Set atable = ActiveDocument.Tables(1)

Set source = atable.Cell(1, 1)

Set myrange = source.Range

myrange.Collapse wdCollapseStart

ActiveDocument.Fields.Add Range:=myrange, Text:="NEXT", _

PreserveFormatting:=False

source.Range.Copy

For j = 2 To atable.Columns.Count

   Set target = atable.Cell(1, j)

   If target.Range.Fields.Count > 0 Then

       target.Range.Paste

   End If

Next j

For i = 2 To atable.Rows.Count

   For j = 1 To atable.Columns.Count

        Set target = atable.Cell(i, j)

        If target.Range.Fields.Count > 0 Then

             target.Range.Paste

        End If

   Next j

Next i

atable.Cell(1, 1).Range.Fields(1).Delete

End Sub

It is suggested that you put this code into a template that you save in the
Word Startup folder so that it becomes an add-in and will be available
whenever you need it.  As the macro has the same name as the Word Command
that is supposed to do the job, this macro will run when the Update Labels
button is used when setting up the mail merge label main document.