OK, unless you are actually using an OpenDataSource to open a data source,
you can't actually use Mailmerge to populate those merge fields for you.
Since you're getting your data from a web service, you probably are not able
to use OpenDataSource because that requires the data to come from a file, or
a type of data source recognised by Word such as OLEDB or ODBC. If you are
able to create a file with a local or Microsoft network address (i.e. one
that you can only open using an Internet URL won't work because
OpenDataSource will not open it) then that is probably the simplest way to
populate your merge fields.

If you cannot do that (e.g. because you are not allowed to create local
files) then the only approach is to replace whatever placeholders exist in
the document with your own data, i.e. simulate a merge. That's what I'm
assuming you are trying to do, and if so:
a. be aware that Mailmerge actually does quite a lot of stuff that it is
non-trivial to write yourself. For example, if for some reason there are
nested fields in your document, you may have to ensure that your code
replaces the placeholders in a specific sequence. Inserting data in headers
and footers can also be tricky if you need to create multi-section documents
as output.
b. you may find it useful to use field types other than MERGEFIELD fields
as placeholders. In particular, you can consider using { DOCVARIABLE } or
{ DOCPROPERTY } fields in the main document - the advantage is that you can
populate the Document variables and/or Document properties in code, then
select the document and re-execute all the fields, and Word will do the
rest. You don't need to find the fields in the document etc. etc. The main
drawback is that if you try to put an empty string in a Document variable,
Word will delete the variable and the { DOCPROPERTY } field will display an
error message when evaluated.
c. if you use that approach, you may need to loop through all the "Stories"
in the document to update the fields, e.g. using the VB.NET equivalent of
the following VBA code:

'---------------
Sub RefreshAllStories()
Dim r As Range
For Each r In ActiveDocument.StoryRanges
 r.Fields.Update
Next
'---------------

Otherwise, to go back to original question, to loop round all the fields in
a document, you need something more like the following, which should find
most of them but may have trouble detecting some fields in the graphics
layer:

'---------------
Sub IterateMergeFields()
Dim r As Range
Dim f As Field
Dim s As Shape
For Each r In ActiveDocument.StoryRanges
 If r.StoryType <> wdTextFrameStory Then
   For Each f In r.Fields
     If f.Type = wdFieldMergeField Then
       ' do whatever you need
     End If
   Next
 End If
Next
For Each s In ActiveDocument.Shapes
 If s.Type = msoTextBox Then
   For Each f In s.TextFrame.TextRange.Fields
     If f.Type = wdFieldMergeField Then
       ' do whatever you need
     End If
   Next
 End If
Next
End Sub

'---------------

To get references to Headers and Footers, use the StoryRanges collection to
access specific types of header and footer, e.g.

ActiveDocument.StoryRanges(wdPrimaryHeaderStory)

You may need to trap errors in the case where the specified Story does not
exist.

Peter Jamieson