I don't know of a simple way to work around this change (which happened in
Office 2002) - the only thing I can suggest is that you construct your own
macro. The following code is untested and is based on Astrid Zeelenberg's
example at the Word MVP site -

http://word.mvps.org/faqs/interdev/sendmailcontent.htm

It really assumes that you have just saved the current document to disk.

Sub SendDocumentInMail()

Dim bStarted As Boolean
Dim oOutlookApp As Outlook.Application
Dim oItem As Outlook.MailItem

On Error Resume Next

'Get Outlook if it's running
Set oOutlookApp = GetObject(, "Outlook.Application")
If Err <> 0 Then
   'Outlook wasn't running, start it from code
   Set oOutlookApp = CreateObject("Outlook.Application")
   bStarted = True
End If

'Create a new mailitem
Set oItem = oOutlookApp.CreateItem(olMailItem)

With oItem
   'Set the recipient for the new email - edit this, or comment this out if
your users should enter the address
  .To = "recipient1@mail.com"
   'Set the recipient for a copy - edit this, or comment this out if your
users should enter the address
   '.CC = "recipient2@mail.com"
   'Set the subject to be the document title
   .Subject = ActiveDocument.BuiltInDocumentProperties("Title")
   'The content of the document is used as the body for the email - change
this to be whatever you want
   '.Body = ActiveDocument.Content
   .Attachments.Add Source:= _
     ActiveDocument.FullName, _
     Type:=olByValue, _
     Position:=1, _
     DisplayName:="my attachment"
   ' in this case, just display the result
   .Display
End With

If bStarted Then
   'If we started Outlook from code, then close it
   oOutlookApp.Quit
End If

'Clean up
Set oItem = Nothing
Set oOutlookApp = Nothing

End Sub

Peter Jamieson