Yes I have some fraction macros and some of the images.  I just don't
remember how I had it put together.  Here is a couple of macros.  The first
inserts a fraction with a EQ field construction, the second directly formats
a fraction:

Public Sub Fraction()

Dim oNum As String
Dim oDen As String
Do
 oNum = InputBox("Enter numerator:", "Numerator")
   If oNum = "" Then
     MsgBox "Numerator cannot be left blank.", , _
     "Illogical expression"
   End If
Loop Until oNum <> ""
Do
 oDen = InputBox("Enter denominator:", "Denominator")
 If oDen = "0" Or oDen = "" Then
   MsgBox "Denominator cannot be zero or left blank.", , _
     "Illogical expression"
 End If
Loop While oDen = "0" Or oDen = ""
If oDen <> "" Then
ActiveDocument.Fields.Add Range:=Selection.Range, _
   Type:=wdFieldEmpty, _
   Text:="EQ \f(" & oNum & ", " & oDen & " )", _
   PreserveFormatting:=False
End If
End Sub

Sub InsertFraction()
Dim Expr As String
Dim Numerator As String
Dim Denominator As String
Dim NewSlashChar As String
Dim SlashPos As Integer
Dim bInvalid As Boolean
NewSlashChar = ChrW(&H2044)

Do
 bInvalid = False
 Expr = InputBox("Enter the fraction as numerator/denominator" _
        & " (e.g., 3/4, a/b, etc.):", "Enter Fraction")
 If Expr = "" Then Exit Sub
 SlashPos = InStr(Expr, "/")
 If SlashPos = 0 Or SlashPos = 1 Then
   bInvalid = True
   MsgBox "Format must be numerator/denominator" _
          & " (e.g., 3/4, a/b, etc.)." _
          & " Please try again.", , "Format Error"
 End If
 Numerator = Left(Expr, SlashPos - 1)
 Denominator = Right(Expr, Len(Expr) - SlashPos)
 If Denominator = "0" Then
   bInvalid = True
   If MsgBox("The denominator is a null value." _
             & " Do you want to override?", vbYesNo, _
             "Illogical Expression") = vbYes Then
         bInvalid = False
   End If
 End If
Loop While bInvalid
Selection.Font.Superscript = True
Selection.TypeText Text:=Numerator
Selection.Font.Superscript = False
Selection.TypeText Text:=NewSlashChar
Selection.Font.Subscript = True
Selection.TypeText Text:=Denominator
Selection.Font.Subscript = False
End Sub