Yes, it is.

In the VBA editor in Excel, click Tools > References. Put a check in the box
next to Microsoft Word Object Library. That gives the Excel macro access to
all the objects, methods, and properties of things in Word.

When you're doing cross-application macros, get in the habit of using the
proper qualifiers for all declarations. For this particular example, you
could declare

  Dim myTable As Table

without getting into any trouble. But there are some objects that have the
same name in Excel and in Word (for example, the Style object). To
distinguish between them, you have to write the declaration as

 Dim myStyle As Word.Style

It wouldn't hurt to write

  Dim myTable As Word.Table

just to make clear what it is.

To see what kind of trouble an unqualified declaration can cause, try
running the following example in Excel after setting the reference to Word,
and read the comments:

Sub Demo()
   Dim wApp As Word.Application
   Dim wDoc As Word.Document
   Dim oStyle As Style  ' implicitly Excel.Style
   Dim owStyle As Word.Style
   Dim sName As String

   ' display the Excel styles -- this works
   For Each oStyle In ActiveWorkbook.Styles
       MsgBox oStyle.NameLocal
   Next

   ' start a Word session with a blank doc
   Set wApp = New Word.Application
   wApp.Visible = True
   Set wDoc = wApp.Documents.Add

   On Error Resume Next
   ' this will get a type mismatch error
   ' because oStyle is an Excel style,
   ' not a Word style:
   Set oStyle = wDoc.Styles("Normal")
   If Err.Number > 0 Then
       MsgBox Err.Description
   End If
   On Error GoTo 0  ' clear the error

   ' the following will work because
   ' owStyle is qualified as a Word style
   For Each owStyle In wDoc.Styles
       sName = owStyle.NameLocal
       If LCase(Left(sName, 1)) = "n" Then
           MsgBox sName
       End If
   Next

   wDoc.Close savechanges:=wdDoNotSaveChanges
   wApp.Quit
End Sub